topic Re: which informat to use when converting characer date time to numeric date time in SAS Programming

which informat to use when converting characer date time to numeric date time

knveraraju91 — Mon, 14 Jan 2019 06:18:19 GMT

Dear,

In my data, the date time variable has the below values. I am using anydtdtm. informat to convert char to numeric, but it is working only for 2nd obs. Which informat should i use to output both rows. Thank you.


data have;
input dtm $19.;
datalines;
2016-06-02T14:44
2016-04-08
;

data want;
set have;
ndtm=input(dtm,anydtdtm.);
format ndtm datetime18.;
run;

Re: which informat to use when converting characer date time to numeric date time

singhsahab — Mon, 14 Jan 2019 07:35:55 GMT

Hello Kn,

I'm not sure which informat needed in this case . But here is an solutions , which may help to fulfill your request .

data want;
set have;
st=compress(substr(scan(dtm,3,'-'),3,1));
if st eq 'T'  then dtm_ = substr(dtm,1,10);
else  dtm_ =dtm;
ndtm=input(dtm_,anydtdte12.);
format ndtm date9.;
drop dtm_ st;
run;

Thanks...

Re: which informat to use when converting characer date time to numeric date time

Kurt_Bremser — Mon, 14 Jan 2019 08:07:56 GMT

You need to be selective with respect to the length of dtm:

data have;
input dtm $19.;
datalines;
2016-06-02T14:44
2016-04-08
;
run;

data want;
set have;
if length(dtm) = 10
then mydtm = dhms(input(dtm,e8601da10.),0,0,0);
else mydtm = input(dtm,e8601dt19.);
format mydtm e8601dt19.;
run;

Note that the informat E8601DA10. is equivalent to YYMMDD10.