topic Re: create a new variable while preserving existing index in SAS Programming

create a new variable while preserving existing index

franriv — Sat, 12 Jan 2019 01:01:01 GMT

data example(index=(my_index=(id visit)));
	input id visit$ visit_num var1 var2 var3;
	datalines;
1 Visit1 1 20 30 35
1 Visit2 2 75 35 45
2 Visit1 3 99 15 34
2 Visit2 4 55 38 48
;
run;

proc contents;

data example;
	set example;
	test=1;
run;

proc contents;

Re: create a new variable while preserving existing index

novinosrin — Sat, 12 Jan 2019 01:10:48 GMT

Interesting question. In your scenario, i'd probably go for proc datasets index create or using proc sql. Well, not claiming anything but just a thought

Re: create a new variable while preserving existing index

Patrick — Sat, 12 Jan 2019 01:26:26 GMT

You can as long as you use logic which doesn't re-create the table.

data example(index=(my_index=(id visit)));
  input id visit$ visit_num var1 var2 var3;
  datalines;
1 Visit1 1 20 30 35
1 Visit2 2 75 35 45
2 Visit1 3 99 15 34
2 Visit2 4 55 38 48
;
run;

/* add column to existing table */
proc sql;
  alter table example
    add test NUM
    ;
quit;

/* populate column with value - option 1*/
proc sql;
  update example
    set test=1
    ;
quit;

/* populate column with value - option 2*/
data example;
  modify example;
  test=2;
run;

proc contents data=example;
run;

Re: create a new variable while preserving existing index

novinosrin — Sat, 12 Jan 2019 01:28:57 GMT

Neat!!!

Re: create a new variable while preserving existing index

VDD — Sat, 12 Jan 2019 01:33:24 GMT

Thanks for the example's and reminder @Patrick,

Re: create a new variable while preserving existing index

franriv — Sat, 12 Jan 2019 01:53:16 GMT

is it possible to do it without using proc sql?

Re: create a new variable while preserving existing index

Tom — Sat, 12 Jan 2019 03:23:39 GMT

Why? If you are adding a column to the dataset then you are making a new dataset.

So just make the new dataset. Create the index as you make the new dataset.

Re: create a new variable while preserving existing index

VDD — Sat, 12 Jan 2019 04:02:08 GMT

any thing is possible. Why make it hard to do? if you want to create a new world then lets do it in DOS.