topic Re: how to find the second capital letter in the data in SAS Programming

how to find the second capital letter in the data

sasismylife — Mon, 07 Jan 2019 10:28:47 GMT

Hi Experts,

i have a data like below in that i need to separate into words only clue we have is starting from the second Upper letter is next word.

for example if your take PraveenKumar i need to separate two words Praveen and Kumar.

Can anyone please help me how to separate the data into two words.

data wanted;

x='PraveenKumar';output;

x='RamSita';output;

x='JorgePaul';output;

run;

Re: how to find the second capital letter in the data

DanielLangley — Mon, 07 Jan 2019 10:51:45 GMT

This solution trawls through the text and puts a space next to any capital letter (so if there are 3 it will turn into 3 words)

data have;
x='PraveenKumar';output;
x='RamSita';output;
x='JorgePaul';output;
run;

data want(drop = i letter);
set have;
attrib y length=$50;
y = "";
do i = 1 to length(x);
	letter = substr(x,i,1);
	if letter = upcase(letter) then y = catx(" ",y,letter);
	else y = cats(y,letter);
end;
run;

Re: how to find the second capital letter in the data

FredrikE — Mon, 07 Jan 2019 11:15:32 GMT

You can solve it by using regular expressions:

data want;
 set wanted;
 a = prxmatch('/[a-z][A-Z]/', x);
 fname = substr(x,1,a);
 lname = substr(x,a+1);
run;

Prxmatch looks for the first combination och lowcase character followed by an uppercase character 🙂

//Fredrik

Re: how to find the second capital letter in the data

sasismylife — Mon, 07 Jan 2019 11:56:54 GMT

Thanks Fredrik for your quick response.:)

Re: how to find the second capital letter in the data

sasismylife — Mon, 07 Jan 2019 11:57:36 GMT

Hi Daniel,

Thanks for your quick response:)

Re: how to find the second capital letter in the data

kiranv_ — Mon, 07 Jan 2019 15:21:04 GMT

data have;

x='PraveenKumar';output;

x='RamSita';output;

x='JorgePaul';output;

run;
data want;
set have;
fname= char(compress(x,,'KU'),1);
lname= char(compress(x,,'KU'),2);
run;

Re: how to find the second capital letter in the data

novinosrin — Mon, 07 Jan 2019 14:54:51 GMT

data have;

x='PraveenKumar';output;

x='RamSita';output;

x='JorgePaul';output;

run;
data want;
set have;
_iorc_=findc (x,,'U');
First_name=substr(x,_iorc_,findc (x,,'U', _iorc_ + 1)-_iorc_);
Last_name=substr(x,findc (x,,'U', _iorc_ + 1));
run;

Re: how to find the second capital letter in the data

novinosrin — Mon, 07 Jan 2019 14:55:40 GMT

Your code is incorrect. Needs tweaking. Char is not the function to use I am afraid

Re: how to find the second capital letter in the data

novinosrin — Mon, 07 Jan 2019 15:07:49 GMT

And another one

data have;

x='PraveenKumar';output;

x='RamSita';output;

x='JorgePaul';output;

run;

data want;
set have;
First_name=substr(x,anyupper (x),anyupper (x,2)-1);
Last_name=substr(x,anyupper(x,2));
run;