topic Re: solution neeeded in SAS Programming

solution neeeded

Guptashwe — Sat, 22 Dec 2018 12:27:15 GMT

how can we print the expected output using characters function

DATA TEST;
INPUT DEPARTMENT $ PRODUCTS $;
DATALINES;
D1 X1
D1 X2
D2 Y1
D2 Y2
D2 Y3
D3 Z1
D3 Z2
D3 Z3
D3 Z4
;
RUN;

expected output

Department Products

D1 X1,X2

D2 Y1,Y2,Y3

D3 Z1,Z2,Z3,Z4

Re: solution neeeded

Jagadishkatam — Sat, 22 Dec 2018 13:40:53 GMT

DATA TEST;
INPUT DEPARTMENT $ PRODUCTS $;
DATALINES;
D1 X1
D1 X2
D2 Y1
D2 Y2
D2 Y3
D3 Z1
D3 Z2
D3 Z3
D3 Z4
;
RUN;

data want;
length PRODUCTS $100.;
set test(rename=(PRODUCTS=_PRODUCTS));
by DEPARTMENT  _PRODUCTS;
retain PRODUCTS;
if first.DEPARTMENT then PRODUCTS=_PRODUCTS;
else PRODUCTS=catx(',',PRODUCTS,_PRODUCTS);
if last.DEPARTMENT;
drop _PRODUCTS;
run;

Re: solution neeeded

r_behata — Sat, 22 Dec 2018 15:50:00 GMT

DATA TEST;
INPUT DEPARTMENT $ PRODUCTS $;
DATALINES;
D1 X1
D1 X2
D2 Y1
D2 Y2
D2 Y3
D3 Z1
D3 Z2
D3 Z3
D3 Z4
;
RUN;

data Want(rename=(products_=products));
if _n_=0 then do;
	set test;
end;
Length products_ $12.;
products_=' ';
do until(last.DEPARTMENT);
set test;
	by department;
	products_=catx(',',products_,products);
end;

drop products;
run;

Re: solution neeeded

novinosrin — Sat, 22 Dec 2018 16:44:28 GMT


DATA TEST;
INPUT DEPARTMENT $ PRODUCTS $;
DATALINES;
D1 X1
D1 X2
D2 Y1
D2 Y2
D2 Y3
D3 Z1
D3 Z2
D3 Z3
D3 Z4
;
RUN;

proc transpose data=test out=t(drop=_name_);
by department;
var products;
run;

data want;
set t;
length products $50;
products=catx(',',of col:);
drop col:;
run;

Re: solution neeeded

mkeintz — Sun, 23 Dec 2018 01:07:04 GMT

If all you really want to do is PRINT the data, then a single DATA _NULL_ step works:

DATA TEST;
INPUT DEPARTMENT $ PRODUCTS $;
DATALINES;
D1 X1
D1 X2
D2 Y1
D2 Y2
D2 Y3
D3 Z1
D3 Z2
D3 Z3
D3 Z4
run;
data _null_;
  file print;
  set test;
  by department;
  if first.department then put / department  @5 products @;
  else put +(-1) ',' products @;
run;

The PUT / says to advance a line.
The trailing @ in a put statement tells SAS to hold the column pointer. So the next PUT statement will not automatically start a new line. Instead it write to the location of the pointer.
The "else put +(-1)" ordinarily uses the + sign to move the column pointer forward. But in this case it's actually "+(-1)" which tells sas to move BACK one column. That's necessary because the trailing @ after a variable name (as opposed to a character literal) actually advances one blank prior to holding the pointer. This overwrites that blank.