Defining a Hash Table with Variables

theponcer — Thu, 20 Dec 2018 21:17:26 GMT

Is there a reason I can't use variables when I am defining a hash table? For example, the code below works:

data out_table;
set base_table;
if 0 then set lookup_table;

if _n_=1 then do;

dcl hash h(dataset: 'lookup_table');
h.definekey('Var1');
h.definedata('Var1','Var2');
h.definedone();
end;

rc_h=h.find();
run;

But THIS doesn't:

%let table_variable = lookup_table;


data out_table;
set base_table;
if 0 then set &table_variable.;

if _n_=1 then do;

dcl hash h(dataset: '&table_variable.');
h.definekey('Var1');
h.definedata('Var1','Var2');
h.definedone();
end;

rc_h=h.find();
run;

Why not?

Re: Defining a Hash Table with Variables

r_behata — Thu, 20 Dec 2018 21:21:05 GMT

Macro variables will not resolve in singe quotes . Try

%let table_variable = lookup_table;


data out_table;
set base_table;
if 0 then set &table_variable.;

if _n_=1 then do;

dcl hash h(dataset: "&table_variable.");
h.definekey('Var1');
h.definedata('Var1','Var2');
h.definedone();
end;

rc_h=h.find();
run;

topic Defining a Hash Table with Variables in SAS Programming

Defining a Hash Table with Variables

Re: Defining a Hash Table with Variables