topic Re: Keep string after a symbol in SAS in SAS Programming

Keep string after a symbol in SAS

mglogan — Wed, 19 Dec 2018 20:37:50 GMT

Hello, I need to create a new variable based on an existing one that contains a value such as: "SV01 â€“ Study visit out of window"

I need to keep everything after the â€“ and remove the leading space so that the new variable contains "Study visit out of window"

the lengths of the input variable are not the same.

Thanks for your help!

Re: Keep string after a symbol in SAS

tomrvincent — Wed, 19 Dec 2018 20:43:13 GMT

1. calc the position of â€“ in the string.
2. substr everything from after that position to the end of the string.

Re: Keep string after a symbol in SAS

novinosrin — Wed, 19 Dec 2018 20:48:01 GMT

data test;
have="SV01 â€“ Study visit out of window";
want=substr(have,find(have,"â€“")+4);
run;

data test;
have="SV01 â€“ Study visit out of window";
want=strip(scan(have,-1,"â€“"));
run;

Re: Keep string after a symbol in SAS

r_behata — Wed, 19 Dec 2018 20:52:42 GMT

data have;
	var1="SV01 â€“ Study visit out of window"; output;
	var1="â€“ SV01 Study visit out of window"; output;
	var1=" SV01  Study visit out of â€“ window"; output;

run;

data want;
Length var1 var2 $100.;
	set have;
	var2=strip(substr(strip(var1),findw(var1,"â€“")+3));
run;

Re: Keep string after a symbol in SAS

mglogan — Wed, 19 Dec 2018 20:53:48 GMT

Thank you!

Re: Keep string after a symbol in SAS

novinosrin — Wed, 19 Dec 2018 20:54:54 GMT

Kindly test thoroughly and come back to us if you jump into some intricacies. Thanks

Re: Keep string after a symbol in SAS

kiranv_ — Wed, 19 Dec 2018 21:33:17 GMT

@novinosrin way is cleaner and simpler and this is just another way using prxchange. brief explanation of prxchange below

^(.+?)? this is first and starting position and indicate that this position could be there or not

(â€“) -- this is second patter and has the symbol thing

(.+)$ -- this is third position after second position till the end

/$3/ -- this means replace everything with third position/pattern

data test;
have="SV01 â€“ Study visit out of window";
want=prxchange('s/^(.+?)?(â€“)(.+)$/$3/', 1, have);
run;

Re: Keep string after a symbol in SAS

ballardw — Wed, 19 Dec 2018 21:16:30 GMT

Because SCAN uses any of the single characters in the third parameter position it may not be the best solution if either the â€ or " might appear anyplace other than as a pair. Example:

data test;
have="SV01 â€“ Study visit out “of window";
want=strip(scan(have,-1,"â€“"));
run;

Which returns "of window" as the value for want since the Scan function is using a single delimiting character and reading from right to left (the -1 parameter) to get the end of the string.

Re: Keep string after a symbol in SAS

novinosrin — Wed, 19 Dec 2018 21:24:46 GMT

This should address that problem, perhaps?

Convert the â€“ to tab delim and the same approach


data test;
have="SV01 â€“ Study visit out “of window";
temp=tranwrd(have,'â€“','09'x);
want=strip(scan(temp,-1,'09'x));
drop temp;
run;

Re: Keep string after a symbol in SAS

ballardw — Wed, 19 Dec 2018 23:51:28 GMT

@novinosrin wrote:

This should address that problem, perhaps?

Convert the â€“ to tab delim and the same approach
data test;
have="SV01 â€“ Study visit out “of window";
temp=tranwrd(have,'â€“','09'x);
want=strip(scan(temp,-1,'09'x));
drop temp;
run;

Yes, something like that or other approaches. I mentioned the issue so if the OP had run the code with SCAN and got unexpected results there would be a place to look for the cause. I will not mention how much time I spend running down similar data issues when provided data that some value "always" occurs with another specific value.