topic Re: PROC FREQ help in SAS Programming

PROC FREQ help

dan999 — Sun, 16 Dec 2018 04:31:50 GMT

Is it possible to do this with proc freq?

data company;
	length co_name $50.;
 	input co_name $ 1-14 name $ 16-18 totalcontacts; 
 	datalines;
AAA Ford - BMC Dan 8
AAA Ford - BMC Jan 6
AAA Ford - BMC Mar 1
AAA Ford - BMC Tom 5
;
run;

proc freq noprint data=company;
	tables  name*totalcontacts/out=work.company2;
run;

I want the output to look like this:

AAA Ford - BMC Dan 40%

AAA Ford - BMC Jan 30%

AAA Ford - BMC Mar 5%

AAA Ford - BMC Tom 25%

Thanks

Re: PROC FREQ help

novinosrin — Sun, 16 Dec 2018 04:59:41 GMT

Very easy and straight forward in sql:

data company;
	length co_name $50.;
 	input co_name $ 1-14 name $ 16-18 totalcontacts; 
 	datalines;
AAA Ford - BMC Dan 8
AAA Ford - BMC Jan 6
AAA Ford - BMC Mar 1
AAA Ford - BMC Tom 5
;
run;
proc sql;
create table company2 as
select co_name,name, totalcontacts/sum(totalcontacts) as pct format=percent.
from company
group by  co_name;
quit;

Re: PROC FREQ help

mkeintz — Sun, 16 Dec 2018 08:07:58 GMT

Yes you can do this with proc freq. However proc freq produces a PERCENT variable that generates the number 20 to represent twenty percent, NOT the number 0.2. The problem is that SAS has a percent. format that shows .2 as 20%, but has none to show 20 as 20%.

You can make your own format if you like:

proc format ;
  picture pct low-high='009%';
run;

proc freq noprint data=company;
	tables  co_name*name/out=work.company2 (drop=count);
	weight totalcontacts;
	format percent pct.;
run;
proc print data=company2;run;

Re: PROC FREQ help

dan999 — Sun, 16 Dec 2018 16:04:21 GMT

I know how to do it in SQL. I thought proc freq might be fewer steps and I'd learn something new. Thanks.

Re: PROC FREQ help

dan999 — Sun, 16 Dec 2018 16:05:05 GMT

So that's how you do it. Thanks for the help.

Re: PROC FREQ help

dan999 — Sun, 16 Dec 2018 16:08:02 GMT

Sorry. Replied to wrong post. Thanks for the help.