topic Re: how to find the variable is numeric or not in SAS Programming

how to find the variable is numeric or not

Aayushi_17 — Mon, 10 Dec 2018 11:50:55 GMT

Hii

I am practicing SAS with dummy datasets i came across this condition where a variables contains both numeric and character .

Data 1	Data 2
present	4
abs	6
12	9
332	.
21	.
31	.
27	4
not defined	7

i got a condition like

(i)if data1 is numeric and data 2 is not missing then data3=data1

(ii) if data 1 is not numeric then data 4 is null

can anyone please help me how to solve this ....thanks in advance

Re: how to find the variable is numeric or not

PeterClemmensen — Mon, 10 Dec 2018 12:31:41 GMT

Use the VTYPE Function

Re: how to find the variable is numeric or not

Ksharp — Mon, 10 Dec 2018 12:19:18 GMT

Check VTYPE() function.

data class;
 set sashelp.class;
 t1=vtype(name);
 t2=vtype(age);
run;

Re: how to find the variable is numeric or not

Aayushi_17 — Mon, 10 Dec 2018 12:20:08 GMT

for vartype we have to use array function....cant we find it out without using array

Re: how to find the variable is numeric or not

PeterClemmensen — Mon, 10 Dec 2018 12:24:45 GMT

Some to think of it, I don't think you are actually interested in the type of the variable. You want to know whether the variable value can be represented as a number, correct?

Re: how to find the variable is numeric or not

Aayushi_17 — Mon, 10 Dec 2018 12:25:51 GMT

if the type of the variable is numeric then i have apply those condition

Re: how to find the variable is numeric or not

Aayushi_17 — Mon, 10 Dec 2018 12:28:31 GMT

what if the number is also stored in character format vtype returns as C even for that

Re: how to find the variable is numeric or not

PeterClemmensen — Mon, 10 Dec 2018 12:29:36 GMT

The type of the Data1 is always character. otherwise the value "present" could not be there. That means that the value "12" is also character here.

Re: how to find the variable is numeric or not

Aayushi_17 — Mon, 10 Dec 2018 12:32:38 GMT

yes

Re: how to find the variable is numeric or not

PeterClemmensen — Mon, 10 Dec 2018 12:37:53 GMT

I think this may be a starting point to what you want to do. Here, I use the INPUT function to determine whether Data1 can be meaningfully represented as a number.

Then I apply your logic to the best of my ability.

data have;
length Data1 $20;
input Data1 $ Data2;
infile datalines dlm=',';
datalines;
present,4
abs,6
12,9
332,.
21,.
31,.
27,4
not defined,7
;

options nonotes;
data want(drop=a);
   set have;
   a=input(Data1, best.);
   if (a ne .) and data2 ne . then data3=a;
   if a eq . then data4=.;
run;
options notes;

Re: how to find the variable is numeric or not

Ksharp — Mon, 10 Dec 2018 12:43:33 GMT

Then Check NOTDIGIT() ANYDIGIT()+COMPRESS().

Re: how to find the variable is numeric or not

Ksharp — Mon, 10 Dec 2018 12:48:31 GMT

Or Try the following code.

data _null_;
 t1='1234.23 ';
 x1=resolve(cats('%datatyp(',t1,')'));
 put t1= x1=;

 t2='23232   ';
 x2=resolve(cats('%datatyp(',t2,')'));
 put t2= x2=;

 t3='2344wew';
 x3=resolve(cats('%datatyp(',t3,')'));
 put t3= x3=;

run;

Re: how to find the variable is numeric or not

RW9 — Mon, 10 Dec 2018 12:55:01 GMT

data want;
  set have;
  if lengthn(compress(data1,"","d"))=0 and data2 ne . then data3=input(data1,best.);
  else data4=.;
run;

Gotta say, you logic doesn't make much sense, data4 will always be . even if the condition else is true.

Re: how to find the variable is numeric or not

PeterClemmensen — Thu, 13 Dec 2018 12:10:47 GMT

@Aayushi_17, let me just emphasize that though I tried to apply your logic, it does not make much sense as data4 will result in a missing value no matter what.

Re: how to find the variable is numeric or not

Aayushi_17 — Thu, 13 Dec 2018 12:30:07 GMT

the numeric is stored in character value which i have to convert and after that i will get the number as output in data 4 and the character values like present will return as null in data 4