topic Re: Histogram / adjust the overall size of the whole plot and custom labels on Y axis in SAS Programming

Histogram / adjust the overall size of the whole plot and custom labels on Y axis

Cruise — Fri, 07 Dec 2018 17:26:44 GMT

Hi Guys,

This histogram is not going my way. I'd like to achieve:

- present the all rows taller so Y-axis would show 0 through 100 by increasing the vertical dimension of the whole plot.

- customize and label GROUPS so it will appear as "benign" instead group=6 and "malignant" instead group=5 so forth so on for all groups.

You help will be greatly appreciated.

Thanks in advance.

proc univariate data=HAVE noprint;
   class GROUP;
   histogram VALUES/ nrows = 6
                     vaxis      =   0  to 100  by  1;
   inset median mean std / pos = ne format = 6.3;
run;

data Have;
do GROUP = 1 to 6;
   do j = 1 to 50;
      VALUES = rand("Normal", Group);
      output;
   end;
end;
run;

Re: Histogram / adjust the overall size of the whole plot and custom labels on Y axis

Rick_SAS — Mon, 26 Nov 2018 19:17:21 GMT

Use the ODS GRAPHICS statement to set the vertical size of the plot.

Use PROC FORMAT to define the categories that you want to use for the GROUP=1 to 6 values:

data Have;
do GROUP = 1 to 6;
   do j = 1 to 50;
      VALUES = rand("Normal", Group);
      output;
   end;
end;
run;

proc format;
value TumorFmt  
      1 = "Benign"
      2 = "Cat 2"
      3 = "Next Value"
      4 = "Another"
      5 = "Almost There"
      6 = "Malignant";
run;

ods graphics / height=1000px width=400px;
proc univariate data=HAVE noprint;
   format GROUP TumorFmt.;
   class GROUP;
   histogram VALUES/ nrows = 6
                     vaxis      =   0  to 100  by  10;
   inset median mean std / pos = ne format = 6.3;
run;