topic Re: How to combine a macro variable value and a text string to create a variable in a data step in SAS Programming

How to combine a macro variable value and a text string to create a variable in a data step

knveraraju91 — Mon, 26 Nov 2018 04:07:02 GMT

Dear,

I need to help in my code in data step two below. In my actual program i had to create a macro variable using proc sql and use it in a data step similar to below.

In data step two below, i need to create variable 'C' with value='TREATEMENT A Respond'. But i am getting errors. Please help. Thank you

%let treat1=TREATMENT A;
%put &treat1.;
data one;
input a b $;
datalines;
1 a
2 b
;

data two;
set one;
if b='a' then do;
c=&treat1.|| 'respond';
end;run;

Re: How to combine a macro variable value and a text string to create a variable in a data step

novinosrin — Mon, 26 Nov 2018 04:23:52 GMT

%let treat1=TREATMENT A;
%put &treat1.;
data one;
input a b $;
datalines;
1 a
2 b
;

data two;
set one;
if b='a' then do;
c="&treat1."|| 'respond';
end;run;

Correction was c="&treat1."|| 'respond';

Re: How to combine a macro variable value and a text string to create a variable in a data step

r_behata — Mon, 26 Nov 2018 05:04:54 GMT

data two;
set one;
if b='a' then do;
c=catx(' ',"&treat1.","respond");
end;
run;

You may also use the CATX function.

Re: How to combine a macro variable value and a text string to create a variable in a data step

Kurt_Bremser — Mon, 26 Nov 2018 08:36:47 GMT

Most simple method:

data two;
set one;
if b = 'a' then c = "&treat1. respond";
run;