topic Re: add quote to value in SAS Programming

add quote to value

jojozheng — Mon, 19 Nov 2018 23:37:00 GMT

hi,

I want to add quote to date value: 30sep2018 30sep2013

my code:

data _null_;
set ret_mon_1; ---------table has date value =30sep2018 and 30sep2013
call symputx('date_last',(put(date, date9.)));
call symputx('date_first',(%quote(put(first_date, date9.))));
put date first_date;
run;

%let date=%sysfunc(cats(%quote(&date_last),d));
%put &date;

I want to call 2 above dates : date='30sep2018'd first_date='30sep2013'd

I don't know why %quote cannot be used.

Re: add quote to value

Reeza — Mon, 19 Nov 2018 23:52:10 GMT

Use the QUOTE not %QUOTE function. Also, if you don't format the dates (using PUT), it will work as desired without any formats.

Re: add quote to value

jojozheng — Mon, 19 Nov 2018 23:54:44 GMT

thank you @Reeza
you mean like below:
call symputx('date_last',(put(date)));
or can you specify for me?

Re: add quote to value

AndrewHowell — Tue, 20 Nov 2018 00:01:49 GMT

@jojozheng.

Broader observation first: you need to better understand the macro scanning process - assignments using & and % commands take place BEFORE data step execution. Please review macro documentation.

If your requirement is to add quotes to existing date value in a data set during execution, then macro assignments are unnecessary - the put() and cat() functions will suffice.

Sample code below. I'm assuming your dates are stored as numerics

data MyDates;
	infile datalines;
	input DateVal:date9.;
	DateStr1=cat("'",put(DateVal,date9.),"'"); /* Surround date with single quotes */
	DateStr2=cat('"',put(DateVal,date9.),'"'); /* Surround date with double quotes */
datalines;
30sep2018
30sep2013
run;

Re: add quote to value

PaigeMiller — Tue, 20 Nov 2018 00:04:57 GMT

Macros are not needed here and in fact just make things much more complicated.

data _null_;
    set ret_mon_1; 
    call symputx('date_last',input(date,date9.));
run;

Also:

I want to call 2 above dates : date='30sep2018'd first_date='30sep2013'd

This really doesn't mean anything to me, Call how? What code will you use them in?

Re: add quote to value

jojozheng — Tue, 20 Nov 2018 00:18:00 GMT

WHEN i %PUT &date_last
it will show in log : '30sep2018'd

Re: add quote to value

Reeza — Tue, 20 Nov 2018 00:27:02 GMT

Yeah, that view is really only good for display, formats are not needed. PUT converts the numeric date to a character variable which is adding work for yourself. If you leave it as a SAS date, which is a number, it will be easier to work with.

Re: add quote to value

Tom — Tue, 20 Nov 2018 01:05:41 GMT

You are working too hard.

First if you already have a macro variable with a value that is compatible with the DATE informat then you can use it directly as a date literal by adding the quotes and trailing d. You do NOT want to use single quotes since the macro variable reference will not resolve inside of single quotes.

%let date_last=30SEP2018;
%let date_literal="&date_last"d;

Second you don't need to use the human readable date literal syntax. You can just use the actual numeric value. So no need for quotes or PUT() function.

Try this code:

data _null_;
  date='30SEP2018'd ;
  first_date='30SEP2013'd;
  call symputx('date_last',date);
  call symputx('date_first',first_date);
  call symputx('date_last_human',quote(put(date,date9.))||'d');
  call symputx('date_first_human',quote(put(first_date,date9.))||'d');
  put (date first_date) (=) ;
  put (date first_date) (= date9.) ;
run;

%put &=date_last &=date_first;
%put &=date_last_human &=date_first_human;

Results:

date=21457 first_date=19631
date=30SEP2018 first_date=30SEP2013
NOTE: DATA statement used (Total process time):
      real time           0.18 seconds
      cpu time            0.01 seconds


1247
1248  %put &=date_last &=date_first;
DATE_LAST=21457 DATE_FIRST=19631
1249  %put &=date_last_human &=date_first_human;
DATE_LAST_HUMAN="30SEP2018"d DATE_FIRST_HUMAN="30SEP2013"d

Re: add quote to value

PaigeMiller — Tue, 20 Nov 2018 12:03:53 GMT

@jojozheng wrote:
WHEN i %PUT &date_last
it will show in log : '30sep2018'd

I'm afraid I don't understand why the end goal is a %PUT statement.

Are you going to use this macro variable somewhere in the rest of your code? If so, you absolutely don't need the quote or the letter "d" at the end, you are working way to hard to accomplish something that is not needed. In that case, you need the macro variable to contain the SAS date value (which is an integer).

Several people have now told you that you don't need a macro variable to contain quotes, that there are simpler ways to get what you want.