topic Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need in SAS Programming

Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

teja04 — Thu, 15 Nov 2018 23:36:32 GMT

Hi All,

I have situation, In ALL_DATASETS folder I have three .sas7bdat files (AA, BB, CC) and I have to read all the files and join datasets from that folder. In the future, I may get one additional dataset (DD) or may not. But, the code should support both the scenarios. could someone help me in that.
Example: I have datasets in path " SAS/sas1/sas_sub1/all_datasets".
In that folder, I have
AA.sas7bdat
BB.sas7bdat
CC.sas7bdat
The dataset expecting will be named as DD.sas7bdat.

Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

teja04 — Thu, 15 Nov 2018 23:34:42 GMT

Hi All,

I have situation, In ALL_DATASETS folder I have three .sas7bdat files (AA, BB, CC) and I have to read all the files and join datasets from that folder. In the future, I may get one additional dataset (DD) or not. But, the code should support both the scenarios. could someone help me in that.
Example: I have datasets in path " SAS/sas1/sas_sub1/all_datasets".
In that folder, I have
AA.sas7bdat
BB.sas7bdat
CC.sas7bdat
The dataset expecting will be named as DD.sas7bdat.

Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

PeterClemmensen — Thu, 15 Nov 2018 23:46:21 GMT

You have to be more specific than "Join datasets from that folder". What kind of join?

Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

teja04 — Thu, 15 Nov 2018 23:55:35 GMT

I want to append the datasets.

Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

teja04 — Thu, 15 Nov 2018 23:58:46 GMT

Hi draycut,

I want to append the datasets

Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

ballardw — Fri, 16 Nov 2018 00:16:33 GMT

The first thing would be to assign a LIBRARY to point to the folder location.

Your example path looks incomplete you should add the bits at the front so that the path starts at a disc or mount point point but generally something like:

libname mydata 'SAS/sas1/sas_sub1/all_datasets';

Check the LOG for messages. If you do not see a successfully assigned result then the path needs to be modified as mentions.

The append can be done with that procedure assuming you have similar variables.

Proc append base=mydata.Alldata

data=mydata.AA;

run;

Proc append base=mydata.Alldata

data=mydata.BB;

run;

Note how the libname is used to address the data sets.

Later to add other sets you just change the name of the set on the DATA= line to add it to the AllData set.

The first time Alldata does not exist so the procedure creates it using the contents of mydata.AA to determine the number and types of variables.

If the sets to do not have the same variables this won't work because append will only add matching variables.

Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

VDD — Fri, 16 Nov 2018 01:49:16 GMT

%let mystr =AA BB CC;

data want;
set &mystr.;
run;

Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

VDD — Fri, 16 Nov 2018 01:57:41 GMT

here is another way but you get all SAS datasets so beware

libname myin "SAS/sas1/sas_sub1/all_datasets";
proc sql ;		
	select 		
		trim(libname) || '.' || memname into :dataset_vars separated by ' '
	from dictionary.tables
	where upcase(libname)="MYIN"
	and upcase(memname) like '%' 
	;
	
quit;

data myin.want;
	set &dataset_vars;
run;

Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

ChrisNZ — Fri, 16 Nov 2018 02:15:00 GMT

Like this?

libname Z '/SAS/sas1/sas_sub1/all_datasets';
data WANT;
  set Z.AA Z.BB Z.CC %sysfunc(ifc(exist(Z.DD),Z.DD,));
run;

Re: Reading multiple .sas7bdat files from folder and select only required datasets whenever we need

Anthony45 — Fri, 16 Nov 2018 02:21:33 GMT

Defining a SAS libref that points to the "SAS/sas1/sas_sub1/all_datasets" path could be an option. You can then simply refer to the datasets by their names using a libname. More info on the libname statement here.

Something like this:

* Define the libname (Note that this statement does not contain an equal sign);
libname my_libname "SAS/sas1/sas_sub1/all_datasets";

* Create a new dataset called 'all_sets' that stacks the 'AA', 'BB', and 'CC' SAS datasets;
data all_sets;
   set my_libname.AA my_libname.BB my_libname.CC;
run;