topic Re: Single and double quote combinations inside a macro? in SAS Programming

Single and double quote combinations inside a macro?

Top_Katz — Mon, 22 Oct 2018 20:11:52 GMT

Hi!

I am editing a macro with the following line:

ods pdf text='^S={preimage="/home/image.jpg"}';

This works as is, but I need to replace the hard-coded string "/home/image.jpg" with a macro variable.

I can get the following to work:

%let cstr = %str('^S={preimage="/home/image.jpg"}');

ods pdf text=&cstr.;

but if I try:

%let cstr = %str(^S={preimage="/home/image.jpg"});

ods pdf text=%str(%')&cstr.%str(%');

I get an error message:

355 ods pdf text='&cstr.';
_
22
_
76
ERROR 22-322: Expecting a quoted string.

ERROR 76-322: Syntax error, statement will be ignored.

How can I get this to resolve properly inside a macro?

Thanks!

Re: Single and double quote combinations inside a macro?

Astounding — Mon, 22 Oct 2018 20:18:53 GMT

Use single quotes on the inside, and double quotes on the outside:

%let cstr = %str(^S={preimage='/home/image.jpg'});

ods pdf text="&cstr.";

Single quotes suppress all macro activity.

Re: Single and double quote combinations inside a macro?

Top_Katz — Mon, 22 Oct 2018 20:47:37 GMT

Thank you, Astounding Super User, that's a useful work around. It's not exactly what I wanted, because I have to pass the string that takes the place of '/home/image.jpg' all inside single quotes, which means I may have to pass it twice, both in and out of the single quotes. But it keeps me going until I find a way to get the macro variable between the single quotes inside the macro code.

Re: Single and double quote combinations inside a macro?

data_null__ — Mon, 22 Oct 2018 21:52:12 GMT

@Top_Katz wrote:

Thank you, Astounding Super User, that's a useful work around. It's not exactly what I wanted, because I have to pass the string that takes the place of '/home/image.jpg' all inside single quotes, which means I may have to pass it twice, both in and out of the single quotes. But it keeps me going until I find a way to get the macro variable between the single quotes inside the macro code.

I may not completely understand all the issues but I like to let SAS do then quoting when that are quotes within quotes.

457  %let cstr = %str(^S={preimage="/home/image.jpg"});
458  %put NOTE: CHECK: %sysfunc(quote(%superq(cstr)));
NOTE: CHECK: "^S={preimage=""/home/image.jpg""}"
459  ods pdf text=%sysfunc(quote(%superq(cstr)));
NOTE: Writing ODS PDF output to DISK destination "sasprt.pdf", printer "PDF".

Re: Single and double quote combinations inside a macro?

Astounding — Tue, 23 Oct 2018 02:09:03 GMT

OK, here's another workaround that you can play with, finding the right spot(s) to use it:

ods pdf text=%unquote(%str(%')&cstr.%str(%'));

Re: Single and double quote combinations inside a macro?

Top_Katz — Tue, 23 Oct 2018 13:12:01 GMT

Thank you, Respected Advisor data_null__, that worked!

Re: Single and double quote combinations inside a macro?

Top_Katz — Tue, 23 Oct 2018 13:12:27 GMT

Thank you, Astounding Super User, that worked!

Re: Single and double quote combinations inside a macro?

Tom — Tue, 23 Oct 2018 13:55:36 GMT

I don't think this is a situation where you need to use single quotes instead of double quotes since you are just generating SAS code.

But when you do need single quotes (for example in pass thru SQL code) then I like to use an %SQUOTE() macro.

Here is one that will work even if you are still running older versions of SAS.

https://github.com/sasutils/macros/blob/master/squote.sas

%macro squote(value);
%if %sysevalf(&sysver < 9.3) %then
%unquote(%str(%')%qsysfunc(tranwrd(%superq(value),%str(%'),''))%str(%'))
;
%else %sysfunc(quote(%superq(value),%str(%'))) ;
%mend squote;