topic Re: split one data set into many in SAS Programming

split one data set into many

Ronein — Tue, 25 Sep 2018 07:14:30 GMT

Hello

I want to split one data set into multiple data sets.

Please find code for 3 ways to do it.

Why way3 is not working? The output data sets are empty.Why???

/*Way1*/
DATA out_Asia;
 set sashelp.cars(where=(origin='Asia'));
run;
DATA out_Europe;
 set sashelp.cars(where=(origin='Europe'));
run;
DATA out_USA;
 set sashelp.cars(where=(origin='USA'));
run;


/*Way2*/
data out_Asia   out_Europe  out_USA;
set sashelp.cars;
   if origin='Asia' then output out_Asia;
   else IF origin='Europe' then output out_Europe;
   else IF origin='USA' then output out_USA;
Run;


/*Way3*/
proc sql noprint;
 select distinct ORIGIN into :valList separated by '+' from SASHELP.CARS trimmed;
quit;
%put &valList;
/*Asia+Europe+USA*/

%let No_arguments=%sysfunc(countw(%str(&valList.),'+'));
%put &No_arguments.;


%macro mmacro1;
%do i=1 %to &No_arguments.;
%let tt=%scan(&valList.,&i.,+);
data out_&tt.; 
set sashelp.cars(where=(origin='tt')); 
run; 
%end;
%mend;
%mmacro1;

Re: split one data set into many

gamotte — Tue, 25 Sep 2018 07:29:43 GMT

Hello,

You forgot to resolve the macrovariable in the where condition

where=(origin="&tt.")

Note that double quotes are necessary for the resolution to take place.

As often said on this forum, splitting a dataset is rarely necessary as most SAS procedures

allow by group processing.

Re: split one data set into many

RW9 — Tue, 25 Sep 2018 07:39:47 GMT

And what benefit will you get from such a process that offsets the downsides of: larger storage needs, slower processing, more complex less robust coding? In almost all cases there is not benefit which outweighs those downsides. Use SAS by group processing, its what it is for.

Re: split one data set into many

DavidBesaev — Mon, 15 Oct 2018 12:17:15 GMT

Hello, @Ronein

I change that row and it has worked:

set sashelp.cars(where=(origin='tt'));

to:

set sashelp.cars(where=(origin="&tt"));

proc sql noprint;
 select distinct ORIGIN into :valList separated by '+' from SASHELP.CARS trimmed;
quit;
%put &valList;
/*Asia+Europe+USA*/

%let No_arguments=%sysfunc(countw(%str(&valList.),'+'));
%put &No_arguments.;


%macro mmacro1;
%do i=1 %to &No_arguments.;
%let tt=%scan(&valList.,&i.,+);
data out_&tt.; 
set sashelp.cars(where=(origin="&tt")); 
run; 
%end;
%mend;