topic Re: concatenate variables with out removing leading and trailing spaces in SAS Programming

concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 08:24:38 GMT

Dear all,

I need to concatenate the 3 variables in to one with out removing leading and trailing blanks.

This is in the datastep.

concatenate = trim(concatenate)||trim(value); --> this will remove the trailing blanks. I don't need to remove any blanks. I need what is exactly in the rows(including trailing and leading blanks).

could any one please help.

INPUT:

MEASURES3=pol_FACPROP sum_pol_FACPROP cnt_pol_OTHER sum_pol_OTHER cnt_ins_COMBINE sum_ins_COMBINE cnt_ins_QA sum_ins_QA cnt_ins_FO sum_ins_FO cnt_ins_FACNP sum_ins_FACNP cnt_ins_PQS sum_ins_PQS cnt_ins_SURPLUS1

MEASURES3= sum_ins_SURPLUS1 cnt_ins_SURPLUS2 sum_ins_SURPLUS2 cnt_ins_FACPROP sum_ins_FACPROP cnt_ins_OTHER sum_ins_OTHER

OUTPUT:

MEASURES3 = cnt_pol_COMBINE sum_pol_COMBINE cnt_pol_QA sum_pol_QA cnt_pol_FO sum_pol_FO cnt_pol_FACNP sum_pol_FACNP cnt_pol_PQS sum_pol_PQS cnt_pol_SURPLUS1 sum_pol_SURPLUS1 cnt_pol_SURPLUS2 sum_pol_SURPLUS2 cnt_pol_FACPROP sum_pol_FACPROP cnt_pol_OTHER sum_pol_OTHER cnt_ins_COMBINE sum_ins_COMBINE cnt_ins_QA sum_ins_QA cnt_ins_FO sum_ins_FO cnt_ins_FACNP sum_ins_FACNP cnt_ins_PQS sum_ins_PQS cnt_ins_SURPLUS1 sum_ins_SURPLUS1 cnt_ins_SURPLUS2 sum_ins_SURPLUS2 cnt_ins_FACPROP sum_ins_FACPROP cnt_ins_OTHER sum_ins_OTHER;

Re: concatenate variables with out removing leading and trailing spaces

gamotte — Thu, 15 Feb 2018 08:44:31 GMT

Hello,

If you want to keep the blanks, don't use the trim function.

Re: concatenate variables with out removing leading and trailing spaces

RW9 — Thu, 15 Feb 2018 09:02:19 GMT

concatenate=cat(concatenate,value);

See the help documentation on all of the concat functions available:

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a002257060.htm

Re: concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 09:18:17 GMT

when using cat(concatenate,value) I am getting null value.

Re: concatenate variables with out removing leading and trailing spaces

RW9 — Thu, 15 Feb 2018 09:46:57 GMT

You asked to keep trailing spaces. That is what it is doing. A text string is is text padded out to the length of the variable with spaces. Therefore if you have concatenate variable set as 200, that is 200 spaces. if value is length 200, and has 4 characters then when you concatenate the variable concatenate, only the first 200 characters are stored, which as that is the first variable is the whole data.

Why not start by postings some test data in the form of a datastep (so we can run it), and what you want out. Is likeli you want a list of variables delimited by a space, so maybe:

data want;
  set have;
  by id;
  want=ifc(first.id,strip(value),catx(' ',want,value));
  if last.id;
run;

This takes the text from value in the first occurence, and concatenates trimmed want, a space, and trimmed value from there after.

Re: concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 09:58:09 GMT

Many Thanks for your explanation.

I need to concatenate the 3 rows exactly. not include any delimeters in between.

you can see in the third macro(below) :

MEASURES3= sum_ins_SURPLUS1 cnt_ins_SURPLUS2 sum_ins_SURPLUS2 cnt_ins_FACPROP sum_ins_FACPROP cnt_ins_OTHER sum_ins_OTHER

There is a leading space. So, during concatenation this should also be there.

Also, maybe in some case there maybe trailing blanks as well, that case also.

hope this helps

Re: concatenate variables with out removing leading and trailing spaces

RW9 — Thu, 15 Feb 2018 10:07:12 GMT

Post test data, your example does not show the required things. All text fields have trailing blanks up to the length of the variable - look at this example:

data want;
  length first $10 second $10 final $21;
  first="abc";
  second="def";
  final=cat(first,'-',second);
run;

What you will see is that I specify the text of first as being "abc", but it is stored as "abc ", because its length is 10. Normally you would need to trim off the additional spaces, but I can't tell from that data wether there should be one space after that text, or 2, or 7? This also shows why presenting test data in the form of a datastep so that we can run it is very important to understanding what you have. Follow this post if your having difficulties:

https://communities.sas.com/t5/SAS-Communities-Library/How-to-create-a-data-step-version-of-your-data-AKA-generate/ta-p/258712

Re: concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 10:34:15 GMT

data a;

input a $1-6 b $7-12;

datalines;

apple rose

apple lotus

;

run;

proc sort data=a;

by a;

quit;

data macros(drop=b);

length concatenate $100;

do until (last.a);

set a;

by a;

concatenate = cat(concatenate,b);

end;

run;

The above is a sample program where cat function is not working for me.

Re: concatenate variables with out removing leading and trailing spaces

RW9 — Thu, 15 Feb 2018 10:37:29 GMT

This will give you a list of all values in b concatenated by a space, all you need to do is add if last.a to get only this record:

data a;
  length a b $10;
  input a $ b $;
datalines;
apple rose
apple lotus
;
run;

proc sort data=a;
  by a;
quit;

data macros (drop=b /*rename=(concatenate=b)*/);
  length concatenate $100;
  retain concatenate;
  set a;
  by a;
  concatenate=ifc(first.a,strip(b),catx(' ',concatenate,b));
run;

Note how I set length on the input variables, and this is less that the 100, so both concatenated are length 20 which will fit in the 100 output variable.

Re: concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 10:48:03 GMT

Yes. Thanks.

But I need a concatenated string without space. :(

Re: concatenate variables with out removing leading and trailing spaces

RW9 — Thu, 15 Feb 2018 10:53:38 GMT

  concatenate=ifc(first.a,strip(b),catx(' ',concatenate,b));

To:

  concatenate=ifc(first.a,strip(b),cat(concatenate,b));

String functions explained:

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a002257060.htm

Re: concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 11:04:02 GMT

concatenate=ifc(first.a,strip(b),cat(concatenate,b))

This is not working

Re: concatenate variables with out removing leading and trailing spaces

RW9 — Thu, 15 Feb 2018 11:34:56 GMT

Cats():

data a;
  length a b $10;
  input a $ b $;
datalines;
apple rose
apple lotus
;
run;

proc sort data=a;
  by a;
quit;

data macros (drop=b /*rename=(concatenate=b)*/);
  length concatenate $100;
  retain concatenate;
  set a;
  by a;
  concatenate=ifc(first.a,strip(b),cats(concatenate,b));
run;

Re: concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 11:58:21 GMT

Thanks. But cats will remove leading and trailing blanks.

In my case, leading and trailing blanks will come. So, I don't want to remove that, I need that as well

Re: concatenate variables with out removing leading and trailing spaces

Satish_Parida — Thu, 15 Feb 2018 12:12:51 GMT

The following is working, tested. No Leading or trailing blanks removed.

data have;
MEASURES1='cnt_pol_COMBINE sum_pol_COMBINE cnt_pol_QA sum_pol_QA cnt_pol_FO sum_pol_FO cnt_pol_FACNP sum_pol_FACNP cnt_pol_PQS sum_pol_PQS cnt_pol_SURPLUS1 sum_pol_SURPLUS1 cnt_pol_SURPLUS2 sum_pol_SURPLUS2 cnt_';
MEASURES2='pol_FACPROP sum_pol_FACPROP cnt_pol_OTHER sum_pol_OTHER cnt_ins_COMBINE sum_ins_COMBINE cnt_ins_QA sum_ins_QA cnt_ins_FO sum_ins_FO cnt_ins_FACNP sum_ins_FACNP cnt_ins_PQS sum_ins_PQS cnt_ins_SURPLUS1';
MEASURES3=' sum_ins_SURPLUS1 cnt_ins_SURPLUS2 sum_ins_SURPLUS2 cnt_ins_FACPROP sum_ins_FACPROP cnt_ins_OTHER sum_ins_OTHER';
MEASURES4=MEASURES1||MEASURES2||MEASURES3;
run;

Please let us know if it worked for you.

Re: concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 12:28:41 GMT

Yes, working..Thanks.

But what happens when it comes to a sas table? It will not work 😞

Here it is a quoted string. But in my case these values are in a sas table.

Re: concatenate variables with out removing leading and trailing spaces

Satish_Parida — Thu, 15 Feb 2018 12:40:54 GMT

In that case this will also work.

There is no space timing, it is old school concatenation.

I have done the same thing in 2 steps just to demonstrate it works.

data have;
MEASURES1='cnt_pol_COMBINE sum_pol_COMBINE cnt_pol_QA sum_pol_QA cnt_pol_FO sum_pol_FO cnt_pol_FACNP sum_pol_FACNP cnt_pol_PQS sum_pol_PQS cnt_pol_SURPLUS1 sum_pol_SURPLUS1 cnt_pol_SURPLUS2 sum_pol_SURPLUS2 cnt_';
MEASURES2='pol_FACPROP sum_pol_FACPROP cnt_pol_OTHER sum_pol_OTHER cnt_ins_COMBINE sum_ins_COMBINE cnt_ins_QA sum_ins_QA cnt_ins_FO sum_ins_FO cnt_ins_FACNP sum_ins_FACNP cnt_ins_PQS sum_ins_PQS cnt_ins_SURPLUS1';
MEASURES3=' sum_ins_SURPLUS1 cnt_ins_SURPLUS2 sum_ins_SURPLUS2 cnt_ins_FACPROP sum_ins_FACPROP cnt_ins_OTHER sum_ins_OTHER';
run;

data want;
set have;
MEASURES4=MEASURES1||MEASURES2||MEASURES3;
run;

For real time,

1. if you know the number of vars you going to concatenate then define the length of final string in advance,

2. Please keep in mind the maximum length of character variables in this case, which is around 32000.

Re: concatenate variables with out removing leading and trailing spaces

Astounding — Thu, 15 Feb 2018 15:23:59 GMT

Assuming

(1) Your incoming data set contains up to 5 observations, and

(2) You are only doing this for one variable (MEASURES3)

(3) The length of VALUE is $ 200:

data want;

set have end=done;

where name='MEASURES3';

length measures3 $ 1000;

retain measures3;

substr(measures3, 1 + 200*(_n_-1)) = value;

if done;

run;

The assumptions can be relaxed, but would require changes to the program. So if the conditions are actually more complex than what you have specified so far, you need to spell them out.

************ EDITED:

Verified that these techniques work. Sample test program:

data test;

input c $char8.;

retain all;

length all $ 24;

substr(all, 1 + (_n_-1)*8) = c;

datalines;

abc

12345678

def

;

proc print; run;

Re: concatenate variables with out removing leading and trailing spaces

chithra — Thu, 15 Feb 2018 13:16:35 GMT

%let path=;
%let server_log=&path./server.log;
%let program_name=start_flexi_dash;

%macro multiple_xml;

	data log_file(keep=txt);
		length org_txt $10000 txt $10000;
		infile "&server_log.";
		input;
		org_txt= _infile_;

		if index(org_txt,"Request body-->") > 0 then
			do;
				txt=substr(org_txt,index(org_txt,"Request body-->")+15,length(org_txt));
				output;
			end;
	run;

	proc sql noprint;
		select count(*) into :count from log_file;
	quit;

	%do i=1 %to &count;

		data _null_;
			set log_file;

			if _N_= &i then
				do;
					file "%sysfunc(pathname(work))/xml_temp.xml";
					put txt;
					call symput("pgm_name",substr(txt,2,find(txt,">",2)-2 ));
				end;
		run;

		%if &pgm_name=&program_name %then
			%do;
				libname lib_xml xml  "%sysfunc(pathname(work))/xml_temp.xml" xmlconcatenate=yes;

				data xml_table;
					set lib_xml.parameters;
				run;

				proc transpose data=xml_table out=xml_trans;
					var _all_;
				run;

				data _null_;
					set xml_trans;
					call symputx(_NAME_,strip(col1),'g');
				run;

			%end;
	%end;
%mend;

%multiple_xml;

proc sql;
	create table vars as
		select name,value from dictionary.macros
			where scope eq 'GLOBAL';
quit;

proc sort data=vars;
	by name;
quit;

data macros(drop=value rename=(concatenate=value));
	length name $100 concatenate $32767;
	do until (last.name);
		set vars;
		by name;
		concatenate = concatenate||value;
	end;
run;

server.log file is below :

Request body--><start_flexi_dash><parameters><MEASURES3>cnt_pol_COMBINE sum_pol_COMBINE cnt_pol_QA sum_pol_QA cnt_pol_FO sum_pol_FO cnt_pol_FACNP sum_pol_FACNP cnt_pol_PQS sum_pol_PQS cnt_pol_SURPLUS1 sum_pol_SURPLUS1 cnt_pol_SURPLUS2 sum_pol_SURPLUS2 cnt_pol_FACPROP sum_pol_FACPROP cnt_pol_OTHER sum_pol_OTHER cnt_ins_COMBINE sum_ins_COMBINE cnt_ins_QA sum_ins_QA cnt_ins_FO sum_ins_FO cnt_ins_FACNP sum_ins_FACNP cnt_ins_PQS sum_ins_PQS cnt_ins_SURPLUS1 sum_ins_SURPLUS1 cnt_ins_SURPLUS2 sum_ins_SURPLUS2 cnt_ins_FACPROP sum_ins_FACPROP cnt_ins_OTHER sum_ins_OTHER</MEASURES3><OE_ID_COUNT>1</OE_ID_COUNT></parameters></start_flexi_dash>

This is my exact program will look like.

please copy the contents and save it as server.log and put the path of the file in the above of the sas program.

The || operator here returns null value.

Can you please check?

Re: concatenate variables with out removing leading and trailing spaces

Tom — Thu, 15 Feb 2018 13:42:20 GMT

@chithra wrote:

data macros(drop=b);

length concatenate $100;

do until (last.a);

set a;

by a;

concatenate = cat(concatenate,b);

end;

run;

The above is a sample program where cat function is not working for me.

The CAT() function is doing what you told it to do. You created CONCATENATE as length 100. You that used CAT() function to create something that was LONGER than 100 characters and store it back into the 100 characters of CONCATENATE. Only the first 100 characters will fit so the value will always contain the 100 spaces that it started with.

WHAT output do you want?

Show both the input and output datasets in the form or working data steps.

Please use the {i} or SAS Running Man icons to post code otherwise the forum editor will re-format the code and any spaces you are trying to show