topic Re: array break until multiple condition met in SAS Programming

array break until multiple condition met

atul_desh — Mon, 17 Sep 2018 17:54:54 GMT

I want to check "FC_2 -- FC_10" column and if FC_* >0 then corresponding "dt_*-1" should populate.

I'm able to do the above task by create code below.

but there is one another constrain if FC_* become zero once again in same row then need to check FC_*>0 once again.

Please help !!

data ds1;
input fc_1-fc_10 (dt_1-dt_10) (:$2.);
datalines;
7 0 8 6 5 0 7 0 0 0 a e a e e a a e a e
7 0 3 10 3 2 10 8 4 7 b d b d d b b d b d
3 0 0 0 2 7 4 4 0 9 f g f g g f f g f g
3 0 0 4 3 10 1 9 4 7 a d a d d a a d a d
;run;

data ds2;
set ds1;

array fc[*] fc_1-fc_10;
array dt[*] dt_1-dt_10;

do i=2 to dim(fc);
if fc[i]>0 then do;
stp_dt=dt[i-1];
leave;

end;
end;
run;

/*output should be like for stp_dt*/
for_first_row = dt_6
for_second_row = dt_2
for_thrid_row = dt_9
for_fourth_row = dt_3

Re: array break until multiple condition met

novinosrin — Mon, 17 Sep 2018 18:02:11 GMT

Do you want to check the last element of the array that is greater than 0 and populate it's ith-1 value of dt array in stp_dt? Just seeking some clarification?

Re: array break until multiple condition met

atul_desh — Mon, 17 Sep 2018 18:11:18 GMT

Not exactly.... if Non-zero occurs and continue till end without getting zero then... its first occurrence -1......

2) if its value become zero again and then again non-zero value then it should chk then newest greater than 0 values ith-1...

a 0 b 2 c 4 d 0 ---> a
a 0 b 0 c 5 d 8 ---> b
a 0 b 3 c 0 d 9 ---> c

Re: array break until multiple condition met

novinosrin — Mon, 17 Sep 2018 18:16:59 GMT

still not sure i comprehend you, see if this is close?


data ds1;
input fc_1-fc_10 (dt_1-dt_10) (:$2.);
datalines;
7 0 8 6 5 0 7 0 0 0 a e a e e a a e a e
7 0 3 10 3 2 10 8 4 7 b d b d d b b d b d
3 0 0 0 2 7 4 4 0 9 f g f g g f f g f g
3 0 0 4 3 10 1 9 4 7 a d a d d a a d a d
;run;


data ds2;
set ds1;
array fc[*] fc_1-fc_10;
array dt[*] dt_1-dt_10;
do i=dim(fc) by -1 until(fc(i)>0);
if fc(i)>0 then stp_dt=dt[i-1];
end;
run;

Re: array break until multiple condition met

atul_desh — Mon, 17 Sep 2018 18:35:08 GMT

Thanks for reply, but not working as expected 😞

data ds1;
input fc_1-fc_10 (dt_1-dt_10) (:$2.);
datalines;
7 0 8 6 5 0 7 0 0 0 a b c d e f g h i j
7 0 3 10 3 2 10 8 4 7 a b c d e f g h i j
3 0 0 0 2 7 4 4 0 9 a b c d e f g h i j
3 0 0 4 3 10 1 9 4 7 a b c d e f g h i j
;run;

data ds2;
set ds1;
array fc[*] fc_1-fc_10;
array dt[*] dt_1-dt_10;
do i=dim(fc) by -1 until(fc(i)>0);
if fc(i)>0 then stp_dt=dt[i-1];
end;
run;

/**output**//

for_first_row = f;

for_second_row = b;

for_third_row = i;

for_fourth_row =b;

Re: array break until multiple condition met

novinosrin — Mon, 17 Sep 2018 18:38:27 GMT

Ok, i think i understand better this time. Let me tweak

Re: array break until multiple condition met

art297 — Mon, 17 Sep 2018 19:01:04 GMT

If your fourth value should really be c rather than b, then the following would work:

data ds1;
  input fc_1-fc_10 (dt_1-dt_10) (:$2.);
  datalines;
7 0 8 6 5 0 7 0 0 0 a b c d e f g h i j
7 0 3 10 3 2 10 8 4 7 a b c d e f g h i j
3 0 0 0 2 7 4 4 0 9 a b c d e f g h i j
3 0 0 4 3 10 1 9 4 7 a b c d e f g h i j
;

data ds2;
  set ds1;
  array fc[*] fc_1-fc_10;
  array dt[*] dt_1-dt_10;
  do i=dim(fc) by -1 until(fc(i-1) eq 0 and fc(i)>0);
    if fc(i-1) eq 0 and fc(i)>0 then stp_dt=dt[i-1];
  end;
run;

Art, CEO, AnalystFinder.com

Re: array break until multiple condition met

novinosrin — Mon, 17 Sep 2018 19:30:32 GMT

elder & wiser but never old at master and hall of famer @art297, Thank you for the lead as it requires a tiny adjustment to meet OP's requirement as I plagiarize yours 🙂


data ds1;
input fc_1-fc_10 (dt_1-dt_10) (:$2.);
datalines;
7 0 8 6 5 0 7 0 0 0 a b c d e f g h i j
7 0 3 10 3 2 10 8 4 7 a b c d e f g h i j
3 0 0 0 2 7 4 4 0 9 a b c d e f g h i j
3 0 0 4 3 10 1 9 4 7 a b c d e f g h i j
;run;

 
data ds2;
set ds1;
array fc[*] fc_1-fc_10;
array dt[*] dt_1-dt_10;
do i=dim(fc) by -1 until(fc(i-1) eq 0 and fc(i)>0);
 if fc(i-1) eq 0 and fc(i)>0 then
 do n=i-1 by -1 while(fc(n)=0);
 stp_dt=dt(n);
 end;
end;
drop i n;
run;

Re: array break until multiple condition met

art297 — Mon, 17 Sep 2018 21:07:41 GMT

@novinosrin: You're assuming that @atul_desh didn't just make an error regarding what was desired for the 4th test case. That may or may not be the case.

If it is, your code as is won't correctly handle a case like:

0 0 0 4 3 10 1 9 4 7 a b c d e f g h i j

Art, CEO, AnalystFinder.com

Re: array break until multiple condition met

novinosrin — Mon, 17 Sep 2018 21:16:05 GMT

I agree

Re: array break until multiple condition met

art297 — Mon, 17 Sep 2018 21:50:31 GMT

@novinosrin: If your assumption is correct your code only needs one escape statement. e.g.:

data ds2;
  set ds1;
  array fc[*] fc_1-fc_10;
  array dt[*] dt_1-dt_10;
  do i=dim(fc) by -1 until(fc(i-1) eq 0 and fc(i)>0);
    if fc(i-1) eq 0 and fc(i)>0 then
     do n=i-1 by -1 while (fc(n) eq 0);
      stp_dt=dt(n);
      if n eq 1 then leave;
     end;
  end;
  drop i n;
run;

Art, CEO, AnalystFinder.com

Re: array break until multiple condition met

novinosrin — Mon, 17 Sep 2018 21:54:32 GMT

Thank you @art297, I am wondering is it possible to get away from linear search? my brain isn't functioning well today

Re: array break until multiple condition met

art297 — Mon, 17 Sep 2018 21:57:08 GMT

Should be away to do it with a regular expression but, again, let's wait to see what @atul_desh really wants.

Art, CEO, AnalystFinder.com

Re: array break until multiple condition met

atul_desh — Tue, 18 Sep 2018 02:16:39 GMT

Thank you all 🙂

below was working fine !!

data ds2;
set ds1;
array fc[*] fc_1-fc_10;
array dt[*] dt_1-dt_10;
do i=dim(fc) by -1 until (fc(i)>0 and fc(i-1)=0) ;
if fc(i)>0 then stp_dt=dt[i-1];
end;
run;

Re: array break until multiple condition met

novinosrin — Tue, 18 Sep 2018 02:39:15 GMT

Thank you for the feedback. So @art297 solutions have always been slick and this one too with no surprises. Please mark torontonian's answer and close the thread. Thank you for the interesting question though.

Re: array break until multiple condition met

Ksharp — Tue, 18 Sep 2018 13:55:18 GMT

data ds1;
  input fc_1-fc_10 (dt_1-dt_10) (:$2.);
  datalines;
7 0 8 6 5 0 7 0 0 0 a b c d e f g h i j
7 0 3 10 3 2 10 8 4 7 a b c d e f g h i j
3 0 0 0 2 7 4 4 0 9 a b c d e f g h i j
3 0 0 4 3 10 1 9 4 7 a b c d e f g h i j
;

data ds2;
  set ds1;
  array fc[*] fc_1-fc_10;
  array dt[*] dt_1-dt_10;
  do i=2 to dim(fc) ;
    if fc(i-1) eq 0 and fc(i)>0 then stp_dt=dt[i-1];
  end;
run;