topic Simulation using SAS in SAS Programming

Simulation using SAS

sousimou — Mon, 17 Sep 2018 08:47:11 GMT

Hi,

Can someone help me in a short sas program to simulate sample variace distribution.

my assumptions are taken from a Normal Sample (N=50, mean =0.01284, var=0.01797).

thank you

sousimou

Re: Simulation using SAS

Ksharp — Mon, 17 Sep 2018 12:52:42 GMT

Check function RAND().

Calling @Rick_SAS

Re: Simulation using SAS

Rick_SAS — Mon, 17 Sep 2018 13:00:39 GMT

Do you want to do this in Base SAS (DATA step and PROC MEANS) or are you planning to do this in SAS/IML?

Re: Simulation using SAS

Rick_SAS — Mon, 17 Sep 2018 13:07:56 GMT

Read the article "Simulation in SAS: The slow way or the BY way" for the basic approach and important ideas. Then modify the second program to use the variance instead of the mean. It should look like this:

/* efficient simulation that calls a SAS procedure */
%let N = 50;
%let NumSamples = 1000;
data Sim(keep=SampleID x); 
do SampleID = 1 to &NumSamples;  /* 1. create many samples */
   do i = 1 to &N;               /* sample of size &N */
      x = rand("Normal", 0.01284, sqrt(0.01797)); /* RAND uses StdDev, not Variance */
      output;
   end;
end;
run;
 
proc means data=Sim noprint; 
   by SampleID;                  /* 2. compute many statistics */
   var x;
   output out=OutStats var=SampleVar;
run;
 
/* 3. analyze the sampling distribution of the statistic */
proc univariate data=OutStats;
   var SampleVar;
   histogram SampleVar / odstitle="Sampling Distribution of Variance"
             href=0.01797;
run;

Re: Simulation using SAS

sousimou — Tue, 18 Sep 2018 07:10:17 GMT

thank you all for your contribution.

The SAS code proposed by Rick is what I was looking for.

thank you Rick