topic The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many arguments in SAS Programming

The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many arguments

martyvd — Tue, 28 Aug 2018 19:06:55 GMT

Please see the following code.

%LET NOMOUNTCYR1 = 'AL';

%LET NOMOUNTCYR1_unquoted=%qsysfunc(compress(&NOMOUNTCYR1,%str(%')));

This successfully removes the single quotes from AL.

%LET NOMOUNTCYR2 = 'GA','MO','NM','OR';

%LET NOMOUNTCYR2_unquoted=%qsysfunc(compress(&NOMOUNTCYR2,%str(%')));

This does not, I get the following error:

ERROR: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many arguments.

Each state abbreviation needs to be in quotes in the original macro variable so it can be used in a where statement later on.

Please help me so that NOMOUNTCYR2_unquoted resolves to GA, MO, NM, OR

Thanks.

Re: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many argume

Reeza — Tue, 28 Aug 2018 19:25:42 GMT

Probably an easier way than this:

%LET NOMOUNTCYR2 = 'GA','MO','NM','OR';

%LET NOMOUNTCYR2_unquoted=%sysfunc(dequote(%sysfunc(translate("&nomountcyr2", " ", "'"))));

%put &NOMOUNTCYR2_unquoted;

I would say create two separate ones from the start if at all possible.

proc sql noprint;
select distinct quote(stateCode, "'"), stateCode 
    into 
        :list1 separated by ",", 
        :list2 separated by ","
from sashelp.zipcode;
quit;

%put List1: &list1.;
%put List2: &list2.;

@martyvd wrote:

Please see the following code.

%LET NOMOUNTCYR1 = 'AL';

%LET NOMOUNTCYR1_unquoted=%qsysfunc(compress(&NOMOUNTCYR1,%str(%')));

This successfully removes the single quotes from AL.

%LET NOMOUNTCYR2 = 'GA','MO','NM','OR';

%LET NOMOUNTCYR2_unquoted=%qsysfunc(compress(&NOMOUNTCYR2,%str(%')));

This does not, I get the following error:

ERROR: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many arguments.

Each state abbreviation needs to be in quotes in the original macro variable so it can be used in a where statement later on.

Please help me so that NOMOUNTCYR2_unquoted resolves to GA, MO, NM, OR

Thanks.

Re: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many argume

novinosrin — Tue, 28 Aug 2018 19:41:03 GMT

you missed to bquote

%LET NOMOUNTCYR2 = 'GA','MO','NM','OR';

%LET NOMOUNTCYR2_unquoted=%qsysfunc(compress(%bquote(&NOMOUNTCYR2),%str(%')));
%put &NOMOUNTCYR2_unquoted;

Re: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many argume

novinosrin — Tue, 28 Aug 2018 19:42:21 GMT

or using %superq

%LET NOMOUNTCYR2 = 'GA','MO','NM','OR';

%LET NOMOUNTCYR2_unquoted=%qsysfunc(compress(%superq(NOMOUNTCYR2),%str(%')));
%put &NOMOUNTCYR2_unquoted;

Re: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many argume

ballardw — Tue, 28 Aug 2018 19:57:35 GMT

@martyvd wrote:

Each state abbreviation needs to be in quotes in the original macro variable so it can be used in a where statement later on.

If your WHERE statement is something like :

Where state in (&NOMOUNTCYR2.) ;

Then you do not need the commas imbedded in the macro variable which are the cause of the too many parameters issue more than likely. The requirement to have commas delimiting items in the IN operator went away maybe in SAS 9.0?

Re: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many argume

martyvd — Tue, 28 Aug 2018 20:12:56 GMT

True, but I failed to mention I also use &NOMOUNTCYR2_unquoted in a output table footnote where I would like the commas to remain.

I specified needing the quotes which I believe are required in the where statement for character variables.

Re: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many argume

Kurt_Bremser — Wed, 29 Aug 2018 06:59:23 GMT

I fully second @Reeza's SQL approach. By far the easier code to read and maintain.

Re: The function COMPRESS referenced by the %SYSFUNC or %QSYSFUNC macro function has too many argume

Reeza — Wed, 29 Aug 2018 15:18:00 GMT

@martyvd There are a few solutions posted that seem correct. Please mark one as the solution if your problem is resolved or clarify if something is still not working.