topic Create a new column with Accum char value in SAS Programming

Create a new column with Accum char value

Ronein — Sun, 26 Aug 2018 11:05:00 GMT

Hello

I have an input table that have one variable called YYMM (Type:char).

This table has only 3 rows with following data:

1807

1806

1712

Task1- Create a new variable called NewVar with following values (type: char):

1807

1807+1806

1807+1806+1712

Thanks

Joe

Task2- Take the last value from NewVar column and create a sas macro varaible called vector

%put &vector will give is value 1807+1806+1712

Data inputTbl;
Input YYMM;
1807
1806
1712
;
Run;

Re: Create a new column with Accum char value

PeterClemmensen — Sun, 26 Aug 2018 11:10:58 GMT

Do like this

data inputTbl;
Input YYMM $;
datalines;
1807
1806
1712
;
Run;

data want;
   set inputTbl end=eof;
   length NewVar $100;
   NewVar=catx('+', NewVar, YYMM);
   retain NewVar;

   if eof then call symputx('vector', NewVar);
run;

%put &vector.;

Re: Create a new column with Accum char value

Kurt_Bremser — Sun, 26 Aug 2018 11:12:25 GMT

Retain the new variable (set a sufficient length), use catx to concatenate the values, and call symput when you reach the end of the dataset (use end= option in the dataset).

Edit: what @PeterClemmensen said 😉

Re: Create a new column with Accum char value

Astounding — Sun, 26 Aug 2018 11:33:03 GMT

Is this just for the sake of building skills? Because you can skip the DATA step and go directly to creating the macro variable:

proc sql;

select MMYY into : vector separated by '+' from have;

quit;