topic Re: Informat for dd/mm/yyyy hh:mm:ss in SAS Programming

Informat for dd/mm/yyyy hh:mm:ss

TW_ — Thu, 23 Aug 2018 12:32:50 GMT

Hi all,

I am currently trying to import a CSV file and keep getting the below Note;

NOTE: Invalid data for STARTDATE in line 2 444-462.

I know that this is being caused due to the data which is trying to be read in is 22/07/2018 09:56:20 in the UK format of dd/mm/yyyy hh:mm:ss but I cannot seem to find the right informat to properly read the data.

I have tried DATE, DATETIME, ANDTTME, even E8601DX (all with a width of 16) but nothing seems to work.

I am using a data step and defining lengths, formats, informats etc., and I am also using SAS EG 7.15 (7.100.5.5850) (64-bit) to access a LINUX server running 9.4.

Any help would be greatly appreciated.

Re: Informat for dd/mm/yyyy hh:mm:ss

Jagadishkatam — Thu, 23 Aug 2018 12:37:50 GMT

Please use the below code in your datastep for the date variable.

data want;
INFILE '/home/test.csv' dsd;
 
 input datevar:ANYDTDTM.;
 
 format datevar DATETIME19.;
put datevar= DATETIME19.;
 
 run;

Re: Informat for dd/mm/yyyy hh:mm:ss

Kurt_Bremser — Thu, 23 Aug 2018 12:47:11 GMT

Personally, I would prefer to force strict formats. I don't trust the guessing involved by using the ANYDTDTM informat.

data want;
input string $19.;
datetime_value = dhms(input(substr(string,1,10),ddmmyy10.),0,0,input(substr(string,12),time8.));
format datetime_value e8601dt19.;
cards;
22/07/2018 09:56:20
;
run;

Re: Informat for dd/mm/yyyy hh:mm:ss

SuryaKiran — Thu, 23 Aug 2018 12:55:18 GMT

You can find the answer by yourself, In SAS EG use the Import Wizard (File>Import Data in SAS Eg) to read the data from CSV. Import wizard will anatomically identify the informat and formats in most of the cases.

It will create the code and you can copy the code and make some changes as per your requirement.

For this scenario it gave me ANYDTDTM19. informat.

Re: Informat for dd/mm/yyyy hh:mm:ss

trt — Mon, 17 Dec 2018 13:19:10 GMT

I have to say this is the worst format to take for import.

ANYDTDTM19. informat is choosing format for each single new line, and makes serious mistakes when month and day can be misunderstood. For example 12JUN2018 (12.06.2018) will by rule always misinterpreted as 06DEC2018.

That is why it is very important to set options datestyle=dmy;

to make it sure that day is read always first.

Re: Informat for dd/mm/yyyy hh:mm:ss

mwstat — Tue, 14 Sep 2021 15:30:00 GMT

Hi,

I tried to use this suggestion to read in data that came to me like this

6/28/2021 22:51

6/28/2021 23:41

6/29/2021 2:18

6/29/2021 5:35

6/29/2021 2:13

I modified the string to be 1,9 and the date to be mmddyy but no luck

Any suggestions?

TIA

Re: Informat for dd/mm/yyyy hh:mm:ss

Kurt_Bremser — Tue, 14 Sep 2021 17:47:33 GMT

You need to adapt the statement to the variable length of the date, the MDY order, and the shorter time:

datetime_value = dhms(input(scan(string,1),mmddyy10.),0,0,input(scan(string,2),time5.));

Re: Informat for dd/mm/yyyy hh:mm:ss

mwstat — Tue, 18 Jan 2022 17:44:04 GMT

Thanks for the suggestions. I wanted to come back and say that I have also had success using

data want1;
set attempt_nov;
time_created1= timepart(DTAttempt);
date_created1 = datepart(DTAttempt);
week1=week(date_created1);
format date_created1 mmddyy10. time_created1 time.;
run;

Re: Informat for dd/mm/yyyy hh:mm:ss

Tom — Tue, 18 Jan 2022 19:17:21 GMT

@mwstat wrote:

Thanks for the suggestions. I wanted to come back and say that I have also had success using

data want1;
set attempt_nov;
time_created1= timepart(DTAttempt);
date_created1 = datepart(DTAttempt);
week1=week(date_created1);
format date_created1 mmddyy10. time_created1 time.;
run;

That will only work if you already have a DATETIME variable, not the character string that the original question is asking about.

Re: Informat for dd/mm/yyyy hh:mm:ss

SanderB — Fri, 20 Jan 2023 10:34:21 GMT

This answer is actually wrong because ANYHDTDTM will assume MM-DD-YYYY first over DD-MM-YYYY. If you give it 12-01-2023 it will read it as the 1st of December, but it should the 12th of January.

Re: Informat for dd/mm/yyyy hh:mm:ss

Kurt_Bremser — Fri, 20 Jan 2023 11:13:37 GMT

@SanderB wrote:
This answer is actually wrong because ANYHDTDTM will assume MM-DD-YYYY first over DD-MM-YYYY. If you give it 12-01-2023 it will read it as the 1st of December, but it should the 12th of January.

This is not (entirely) correct. The ANY... informats will prefer DMY or MDY depending on the DATESTYLE system option (which has a default setting of LOCALE, which means the current locale setting also influences the date order).