topic Re: How to make part of the variable bold in report in SAS Programming

How to make part of the variable bold in report

jk8668 — Sun, 12 Aug 2018 15:15:00 GMT

Hi, please let me know if anyone knows how to do the following.

I am combining 2 variables (Variable1 and Variable2) and creating a new variable. I am using this New variable in generating RTF file.

How can I make part of this New variable (Variable 2) in BOLD in the RTF file?

New Variable= Variable1+ Variable 2

Re: How to make part of the variable bold in report

Dinesh2 — Sun, 12 Aug 2018 20:23:12 GMT

The closest answer I found is on this link: http://www2.sas.com/proceedings/forum2007/151-2007.pdf.

However, when you output the rtf file and open it with microsoft word, you should be able to use the bold option I suppose. Hope this helps.

Re: How to make part of the variable bold in report

Vince_SAS — Mon, 13 Aug 2018 11:32:18 GMT

Does this give you the desired result?

*  Close all open ODS destinations;

ods _all_ close;

*  Create the sample data;

data work.test;
new_variable = 'This text is normal weight ' ||
               '^{style [font_weight=bold]and this text is bold}';
run;

*  Define the escape character;

ods escapechar='^';

*  Create the output using various destinations;

ods html  file='test.html' path='C:\temp';
ods pdf   file='C:\temp\test.pdf';
ods rtf   file='C:\temp\test.rtf';
ods Excel file='C:\temp\test.xlsx';

proc print data=work.test; run; quit;

ods _all_ close;

Vince DelGobbo

SAS R&D

Re: How to make part of the variable bold in report

jk8668 — Mon, 13 Aug 2018 16:13:15 GMT

Thanks Vince.

It's not working for my scenario. The variable is not resolving in the RTF file, it's just printing the variable name.

For ex: I am combining AGE and SEX variables and creating new variable AGESEX. When I generate an RTF file, I want SEX part in BOLD and age in normal font.

When I used your code to generate RTF, instead of printing the values of SEX (Male or Female), it was printed as SEX in BOLD.

EX:

SUBJECT AGESEX

1 43SEX

2 23SEX

3 32SEX

Re: How to make part of the variable bold in report

Vince_SAS — Mon, 13 Aug 2018 16:47:09 GMT

Try this:

*  Close all open ODS destinations;

ods _all_ close;

*  Create the sample data;

data work.class;
set sashelp.class;
length agesex $100;
agesex = strip(put(age, best.)) ||
               '^{style [font_weight=bold]' || strip(sex) || '}';
run;

*  Define the escape character;

ods escapechar='^';

*  Create the output using various destinations;

ods html  file='test.html' path='C:\temp';
ods pdf   file='C:\temp\test.pdf';
ods rtf   file='C:\temp\test.rtf';
ods Excel file='C:\temp\test.xlsx';

proc print data=work.class; 
  var agesex;
run; quit;

ods _all_ close;

Vince DelGobbo

SAS R&D

Re: How to make part of the variable bold in report

jk8668 — Sat, 18 Aug 2018 15:50:48 GMT

Thanks so much vince_sas. It's working.

Re: How to make part of the variable bold in report

jk8668 — Sat, 18 Aug 2018 15:53:09 GMT

Thanks Dinesh