topic Re: proc means with proc format in SAS Programming

proc means with proc format

Ronein — Thu, 09 Aug 2018 10:56:19 GMT

I am using proc means with proc format.

In the output data set in column x I can't see the groups that I defined in proc format.

Why?

How can I solve it?

proc format;
value ffmt
0-10='0-10'
10-50='10-50'
50-100='50-100'
100-high='100+'
;
run;
data tbl;
input ID x  y;
cards;
1 0 100
2 5 110
3 30 120
4 40 130
5 50 140
6 60 150
7 70 160
8 80 170
9 90 180
10 110 190
;
run;
proc means data=tbl nway noprint;
class x;
var y;
format x  ffmt.;
output out=output sum(y)=sum_y;
run;

Re: proc means with proc format

PeterClemmensen — Thu, 09 Aug 2018 11:05:53 GMT

First of all, remember to control your ranges. Eg, what group did you expect the value 10 to be in? Do like this

proc format;
value ffmt
0-10='0-10'
10<-50='10-50'
50<-100='50-100'
100<-high='100+'
;
run;

Also, what is wrong with your output data set? When I run this, I see exactly the groups you have defined?

Re: proc means with proc format

Astounding — Thu, 09 Aug 2018 11:07:42 GMT

The FORMAT statement within PROC MEANS has a temporary effect. It groups the CLASS variable while PROC MEANS runs, but it does not permanently associate the CLASS variable with the format. You would need to repeat the FORMAT statement in a later step to see the formatted values instead of the actual values.

Re: proc means with proc format

Kurt_Bremser — Thu, 09 Aug 2018 11:09:50 GMT

Works for me:

proc format;
value ffmt
0-10='0-10'
10-50='10-50'
50<-100='50-100'
100<-high='100+'
;
run;
data tbl;
input ID x  y;
cards;
1 0 100
2 5 110
3 30 120
4 40 130
5 50 140
6 60 150
7 70 160
8 80 170
9 90 180
10 110 190
;
run;
proc means data=tbl nway noprint;
class x;
var y;
format x  ffmt.;
output out=output sum(y)=sum_y;
run;

proc print data=output noobs;
run;

Result:

  x       _TYPE_    _FREQ_    sum_y

0-10         1         2       210 
10-50        1         3       390 
50-100       1         4       660 
100+         1         1       190

Re: proc means with proc format

ballardw — Thu, 09 Aug 2018 15:29:08 GMT

How did you examine the OUTPUT data set?

The output I get when using proc print on the output data set is:

Proc print data=output noobs;

run;

x	_TYPE_	_FREQ_	sum_y
0-10	1	2	210
10-50	1	3	390
50-100	1	4	660
100+	1	1	190

Re: proc means with proc format

Ronein — Sun, 12 Aug 2018 08:47:05 GMT

If you look at the output data set (and not the output printed) you will see that in X column values are different