topic Re: .txt output with fixed columns in SAS Programming

.txt output with fixed columns

jeninemilum — Wed, 08 Aug 2018 15:30:11 GMT

I am trying to create .txt output with column names and output in columns. I've tried Proc Export, Data _null_ with Puts, ODS (multiple versions). The results I keep getting returned is warped text. I need columns.

Here are 3 of my many attempts:

proc export data=sashelp.class

outfile="/home/jm25324/class.txt"

dbms=tab replace ;

run;

data _null_; set sashelp.class ;

file '/home/jm25324/test.txt' dlm=",";

If _n_=1 then do;

put 'Name, Sex, Age, Height, Weight';

end;

put name sex age height weight;

run;

ods csvall file='/home/jm25324/test5.txt' ;

proc report data=sashelp.class nocenter headline headskip spacing=10 nowd;

column name sex age height weight;

define name / display order "Name" left width=40 ;

define sex / display "Sex" left width=40 flow;

define age / display "Age" left width=40 flow;

define height / "Height" left width=40 flow;

define weight / "Weight" left width=40 flow;

run;

ods csvall close;

Thanks!

Re: .txt output with fixed columns

PeterClemmensen — Wed, 08 Aug 2018 15:43:30 GMT

You can use the column pointer @ like this

data _null_; 
  set sashelp.class ;
  file '/home/jm25324/test.txt';
  If _n_=1 then do;
     put @1 'Name' @ 20 'Sex' @25 'Age' @30 'Height' @40 'Weight';
  end;
  put @1 name @ 20 sex @25 age @30 height @40 weight;
run;

Re: .txt output with fixed columns

Cynthia_sas — Wed, 08 Aug 2018 15:50:00 GMT

Hi:

I'm not sure of the purpose of fixed width columns with a comma separator. Do you mean something like this? I'd do it using full control of my PUT statements:

I don't really understand what you mean when you say "with column names and output in columns" but this is how I interpreted it.

Cynthia

Re: .txt output with fixed columns

ballardw — Wed, 08 Aug 2018 16:29:56 GMT

Fixed column normally means something like variable 1 will occupy columns 1 through 10, variable 2 columns 11 to 17, variable 3 columns 18 to 25 for example and no specific character between values though spaces occur if the length of the variable value is smaller than the space used.

Is that what you want? You are showing comma separated values in your header row in the data _null_ data step and requesting comma separated columns in for the proc report output.

Perhaps you are looking for something like:

ods listing file='/home/jm25324/test5.txt';
proc print noobs data=sashelp.class;
run;
ods listing close;

Re: .txt output with fixed columns

jeninemilum — Thu, 09 Aug 2018 14:25:22 GMT

Here is the solution using the options TERMSTR=crlf:

data _null_;
set sashelp.class ;
file '/home/jm25324/test6.txt' TERMSTR=crlf;
If _n_=1 then do;
put @1 'Name' @ 20 'Sex' @25 'Age' @30 'Height' @40 'Weight';
end;
put @1 name @ 20 sex @25 age @30 height @40 weight;
run;