topic Re: how to derive first name ,lastname,dob from a string in SAS Programming

how to derive first name ,lastname,dob from a string

thanikondharish — Sun, 29 Jul 2018 08:22:16 GMT

data s;
name='ram28062018kumar' ;
output ;
name='venkat15072018sharma' ;
output;
run;

/*this my code to extract first name ,last name,dob.

is there any other coding?*/

data s1 ;
set s ;
finame=substr(name,1,anydigit(name)-1) ;
laname=reverse(substr(reverse(name),1,anydigit(reverse(name))-1));
dob1=compress(name,' ','kd') ;
dob= input(compress(substr(dob1,1,2)||'-'||substr(dob1,3,2)||'-'||substr(dob1,5,4)),ddmmyy10.);
format dob ddmmyyd10. ;
drop dob1;
run;

Re: how to derive first name ,lastname,dob from a string

PeterClemmensen — Sun, 29 Jul 2018 08:29:44 GMT

What do you mean by "is there any other coding?"?

Your code does what it is suppose to, it seems?

Re: how to derive first name ,lastname,dob from a string

thanikondharish — Sun, 29 Jul 2018 08:32:42 GMT

i mean any other short way

Re: how to derive first name ,lastname,dob from a string

Kurt_Bremser — Sun, 29 Jul 2018 10:51:56 GMT

You don't need to insert hyphens in the date string; just use the ddmmyy8. informat.

Otherwise, your code looks fine.

Re: how to derive first name ,lastname,dob from a string

Astounding — Sun, 29 Jul 2018 13:48:26 GMT

You don't really need to create dob1:

dob = input(compress(name,,'kd'), ddmmyy8.);

Re: how to derive first name ,lastname,dob from a string

mkeintz — Sun, 29 Jul 2018 15:21:40 GMT

You've already have good advice on getting dob. Here's a simplication for first and last names:

  fname=scan(name,1,'0123456789');
  lname=scan(name,-1,'0123456789');

The "-1" argument for scan in the lname assignment says to count backwards from the right-most word. This mean you don't have to worry about how many digits are in the dob value.