topic Re: Merging dummy dataset to create structure in SAS Programming

Merging dummy dataset to create structure

gpv2000 — Mon, 23 Jul 2018 19:53:12 GMT

My seq variable goes from 1 to 6, but in my dataset the seq variable ends at 3. For graphing purposes i need to create a dataset as shown in my desired output below.

data have;
input subject	seq	source	max	min;
datalines;
12345	1	1	10	0
23456	2	1	10	0
34567	3	1	10	0
45678	4	1	10	0
56789	5	1	10	0
67890	6	1	10	0
78901	1	2	45	0
89012	2	2	45	0
90123	3	2	45	0

;
run;

I need to add observations to my original dataset, to complete the seq variable to 6. My max and min are related to source. So the additional observations will have respective source,max and min.

subject	seq	source	max	min
12345	1	1	10	0
23456	2	1	10	0
34567	3	1	10	0
45678	4	1	10	0
56789	5	1	10	0
67890	6	1	10	0
78901	1	2	45	0
89012	2	2	45	0
90123	3	2	45	0
	4	2	45	0
	5	2	45	0
	6	2	45	0

Any suggestions?

Re: Merging dummy dataset to create structure

PeterClemmensen — Mon, 23 Jul 2018 20:08:14 GMT

data have;
input subject	seq	source	max	min;
datalines;
12345	1	1	10	0
23456	2	1	10	0
34567	3	1	10	0
45678	4	1	10	0
56789	5	1	10	0
67890	6	1	10	0
78901	1	2	45	0
89012	2	2	45	0
90123	3	2	45	0

;
run;

data want;
   set have end=eof;
   if eof then do while(seq<6);
      seq+1;
      call missing(subject);
      output;
   end;
   retain seq source	max min;
   if seq < 6 then output;
run;

@gpv2000 For what graphing purposes do you need this?

Re: Merging dummy dataset to create structure

novinosrin — Mon, 23 Jul 2018 20:01:45 GMT

data  have;
input subject	seq	source	max	min;
datalines;
12345	1	1	10	0
23456	2	1	10	0
34567	3	1	10	0
45678	4	1	10	0
56789	5	1	10	0
67890	6	1	10	0
78901	1	2	45	0
89012	2	2	45	0
90123	3	2	45	0

;
run;

data want;
set have end=last;
output;
if last then do;
do seq=seq+1 to 6;
call missing(subject);
output;
end;
end;
run;

Re: Merging dummy dataset to create structure

PGStats — Mon, 23 Jul 2018 20:31:02 GMT

If you are using ODS graphics, have you considered options MIN= and MAX= in the XAXIS, COLAXIS, ROWAXIS, and YAXIS statements?

Re: Merging dummy dataset to create structure

gpv2000 — Mon, 23 Jul 2018 20:34:55 GMT

Thank you. It does what I need, but i have a question. I believe I will have to add the variables i need to keep missing next to usubjid. How do I add variables if i have various such as week1,week2,weekn etc?

Re: Merging dummy dataset to create structure

novinosrin — Mon, 23 Jul 2018 20:36:43 GMT

if the list is a pattern, like week1-weekN

you could use call missing(of week: ) ;

Re: Merging dummy dataset to create structure

gpv2000 — Mon, 23 Jul 2018 21:01:44 GMT

Thank you.

Re: Merging dummy dataset to create structure

gpv2000 — Mon, 23 Jul 2018 21:03:05 GMT

I am fairly new sas user. I believe i am not using ODS graphics. But I will look it up now.