topic Re: Base SAS in SAS Programming

How to reference character variables?

petlove — Fri, 20 Jul 2018 19:33:28 GMT

Hi all,

Can we write IF condition for all character variables of dataset without mentioning their names in sas steps?

Thank you.

Re: Base SAS

Reeza — Fri, 20 Jul 2018 19:01:51 GMT

It depends.

@petlove wrote:

Hi all,

Can we write IF condition for all character variables of dataset without mentioning their names in sas steps?

Thank you.

Re: Base SAS

ballardw — Fri, 20 Jul 2018 19:30:14 GMT

@petlove wrote:

Hi all,

Can we write IF condition for all character variables of dataset without mentioning their names in sas steps?

Thank you.

Provide a concrete example of what you want to accomplish. Depending on what the "if condition" is supposed to accomplish can make a big difference on what can be done.

If you want to do something with each variable at a time, probably yes. If you mean all variables at once then most likely no.

In between those two it really really depends on what you are trying to do as to the likelihood of practicality and complexity of code.

Re: How to reference character variables?

Reeza — Fri, 20 Jul 2018 19:34:16 GMT

https://blogs.sas.com/content/iml/2018/05/29/6-easy-ways-to-specify-a-list-of-variables-in-sas.html

PS. I modified your subject line as it was vague and non-informative.

Re: How to reference character variables?

PGStats — Fri, 20 Jul 2018 19:51:07 GMT

Sometimes, yes... For example,

if you want to check for empty strings

if cmiss(of _character_) > 2 then delete;

if you want to check for the presence of a word

if whichc("Error", of _character_) > 0 then delete;

if you want to check for the presence of special characters

if anycntrl(cats(of _character_)) > 0 then delete;

you get the idea...

Re: Base SAS

petlove — Fri, 20 Jul 2018 21:12:11 GMT

Thank you for your response.

I am replacing missing values of character variables to '--' and numeric values to 0 by using below array:

array charv(*) _character_;
do _n_ =1 to dim(charv);
charv(_n_)=coalescec(charv(_n_), '--');
end;

array numv _numeric_;
do over numv ;
if numv =. then numv =0;
end;

When I run this code for any dataset and if dataset does not have character variable it shows below WARNING. In order to avoid, i was thinking to write IF condition.

WARNING: Defining an array with zero elements.

Thank you.

Re: Base SAS

PGStats — Fri, 20 Jul 2018 21:34:50 GMT

Do this instead

_dumx = 999;
_dumc = "X";
array charv(*) _character_;
do _n_ =1 to dim(charv);
    charv(_n_)=coalescec(charv(_n_), '--');
    end;

array numv _numeric_;
do _n_ = 1 to dim(numv) ;
    numv(_n_) = coalesce(numv(_n_), 0);
    end;
drop _dum: ;

Re: Base SAS

Tom — Fri, 20 Jul 2018 22:07:14 GMT

To eliminate the warning you can force SAS to create new variables and then drop them.

Pick names that you know your real data will never have.

Here is example you can run that uses SASHELP.CLASS and drops all of the numeric or characfer variables on the way in.

data test_nochar;
  set sashelp.class(drop=_character_) ;
  array _1 _numeric_ _drop_numeric_;
  array _2 _character_ _drop_character_ ;
  drop _drop_numeric_ _drop_character_ ;
  do over _1; _1=coalesce(_1,0); end;
  do over _2; _2=coalescec(_2,'--'); end;
run;

data test_nonumb;
  set sashelp.class(drop=_numeric_) ;
  array _1 _numeric_ _drop_numeric_;
  array _2 _character_ _drop_character_ ;
  drop _drop_numeric_ _drop_character_ ;
  do over _1; _1=coalesce(_1,0); end;
  do over _2; _2=coalescec(_2,'--'); end;
run;