topic use value of one variable to reference another variable in SAS Programming

use value of one variable to reference another variable

Steelers_In_DC — Thu, 19 Jul 2018 18:24:34 GMT

I am trying to use the value of one variable to reference another variable.

data have;
input one two three value$;
cards;
1 2 3 two
1 2 3 .
1 2 3 one
;
run;

data want;
input one two three;
cards;
1 . 3
1 2 3
. 2 3
;
run;

In row one the variable value = 'two', so I want the variable two to = null. In row value is null so there is no action. In row three value = 'one' so the variable one is changed to null. If anyone can help do this I'd appreciate it. I'm trying to use vvaluex() to do this but not getting there.

Cheers,

Re: use value of one variable to reference another variable

novinosrin — Thu, 19 Jul 2018 18:35:54 GMT

data have;
input one two three value$;
cards;
1 2 3 two
1 2 3 .
1 2 3 one
;
run;

data want;
set have;
array t(*) one--three;
do _n_=1 to dim(t);
if vname(t(_n_))=value then call missing(t(_n_));
end;
drop value;
run;

Re: use value of one variable to reference another variable

ballardw — Thu, 19 Jul 2018 23:10:36 GMT

You may want to check case of your variable name and the value as variable names can be stored in mixed case.

data have;
input One two three value $;
cards;
1 2 3 two
1 2 3 .
1 2 3 one
;
run;

data want;
  set have;
  array a one two three;
  do i = 1 to dim(a);
   if vname(a[i]) = value then a[i]=.;
  end;
  drop i value;
run;

Does not set the missing value on the third row because the case comparison doesn't match. Better might be:

   if upcase( vname(a[i]) ) = upcase( value) then a[i]=.;