Error when trying to apply user-defined format

kimdukes77 — Wed, 18 Jul 2018 12:23:32 GMT

I have inherited some code that creates a user-defined function and format (later used in proc tabulate statement) that is not working.

Can anyone help?

Code below:-

* Create a function that rounds small & missing numbers to zero (amended fromn standard supprnd function code as in this instance we need to create a numeric variable for later calculations);
proc fcmp outlib=work.functions.misc;
function suppf(x);
length y 16;
if ( missing(x) OR x in (1, 2) ) then y = 0; /* suppress disclosive values */
else do;
x2 = round(x, 5); /* round to nearest 5 */
y = put(x2, 32.);
end;
return(compress(y));
endsub;
/*Add function to round to nearest 10 for current cycle reporting*/
function suppt(x);
length y 16;
if ( missing(x) OR x in (1, 2) ) then y = 0; /* suppress disclosive values */
else do;
x2 = round(x, 10); /* round to nearest 5 */
y = put(x2, 32.);
end;
return(compress(y));
endsub;

/* suppress disclosive values, but do not round other values */
function suppr_s(x) $;
length y $30;
if ( missing(x) OR x in (1, 2) ) then y = '--'; /* suppress disclosive values */
else do;
y = put(x, 32.);
end;
return(compress(y));
endsub;
run;

proc format;
/* Format for rounding */
value supp_t
other = [suppt()]; /* suppress disclosive values & round to nearest 10 */
value supp_f
other = [suppf()]; /* suppress disclosive values & round to nearest 5 */
value suppress
other = [suppr_s()]; /* suppress disclosive values only */
quit;

Re: Error when trying to apply user-defined format

Ksharp — Wed, 18 Jul 2018 13:03:26 GMT

Add an option before PROC FORMAT.

options cmplib=work.functions ;

proc format...........

.......

Re: Error when trying to apply user-defined format

kimdukes77 — Wed, 18 Jul 2018 13:16:47 GMT

Works a treat - thank you!

Re: Error when trying to apply user-defined format

FreelanceReinh — Wed, 18 Jul 2018 13:16:49 GMT

@Ksharp wrote:

Add an option before PROC FORMAT.

options cmplib=work.functions ;

proc format...........

.......

... and use the function names as format names (see documentation), i.e. value suppt etc.

topic Re: Error when trying to apply user-defined format in SAS Programming

Error when trying to apply user-defined format

Re: Error when trying to apply user-defined format

Re: Error when trying to apply user-defined format

Re: Error when trying to apply user-defined format