topic Re: Multiplying a dataset in SAS Programming

Multiplying a dataset

Son_Of_Krypton — Fri, 13 Jul 2018 12:03:16 GMT

data number;
input number;
cards;
1
2
3
4
5
;
run;

i want output like this :

please suggest a way to do this

Re: base sas

Amir — Fri, 13 Jul 2018 11:43:34 GMT

Hi,

As you just want a suggestion, see what the following does then try and change it to suit your needs. The input data set has 19 observations, but it is being read twice:

data want;
   set sashelp.class
       sashelp.class
   ;
run;

If you are new to SAS, they do have some basic free training and paid-for training options available:

http://support.sas.com/training/

If you are still stuck then show us what code you have tried and the log with any messages.

Regards,

Amir.

Re: base sas

PeterClemmensen — Fri, 13 Jul 2018 11:56:09 GMT

Why do you want to do this?

One way (among many).

data number;
input number;
cards;
1
2
3
4
5
;
run;

data want;
   set number;
   do i=1 to 3;
      output;
   end;
run;

proc sort data=want out=want(drop=i);
   by i;
run;

Re: Multiplying a dataset

Kurt_Bremser — Fri, 13 Jul 2018 12:04:46 GMT

Another idea, in one data step:

data want;
do i = 1 to 3;
  do j = 1 to nobs;
    set number nobs=nobs point=j;
    output;
  end;
end;
drop i j;
stop;
run;

PS and use more intelligent subjects in the future. "base sas" in the Base SAS Programming community is not meaningful AT ALL..

Re: Multiplying a dataset

data_null__ — Fri, 13 Jul 2018 13:54:18 GMT

proc surveyselect out=number3 reps=3 rate=1 noprint;
   run;

Re: Multiplying a dataset

novinosrin — Fri, 13 Jul 2018 13:57:44 GMT

data number;
input number;
cards;
1
2
3
4
5
;
run;

data want;
set number number number;
run;

Re: Multiplying a dataset

novinosrin — Fri, 13 Jul 2018 14:03:15 GMT

proc sql;
create table want as
select b.number 
from number(where=(number<=3)) a, number b
order by a.number,b.number;
quit;

Re: Multiplying a dataset

novinosrin — Fri, 13 Jul 2018 14:05:43 GMT

data want;
set number(where=(number<=3));
do _n_=1 to nobs;
set number nobs=nobs point=_n_;
output;
end;
run;

Re: Multiplying a dataset

novinosrin — Fri, 13 Jul 2018 14:17:19 GMT

data want;
   if _N_ = 1 then do;
   if 0 then set number;
    dcl hash h(dataset:"number", ordered: 'yes');
    dcl hiter i('h');
      h.defineKey('number');
      h.defineData('number');
      h.defineDone();
   end;
set number (where=(number<=3));
do while (1);
if i.next() ne 0 then return;
  output;
end;
run;