topic Re: Hash Tables in SAS Programming

Using hash tables

astha8882000 — Thu, 12 Jul 2018 13:18:20 GMT

I have a dataset created 'abc' in a sasgrid location

I'm creating another dataset 'xyz' through that using hash table, for eg.,

data xyz;

if _n_=1 then do;

dcl hash hh (dataset: 'abc');

hh.definekey ('phoneno');

hh.definedone();

end;

followed by a bunch of keep statements

run;

when I try and run this, I get the following 2 errors:

ERROR: Undeclared key symbol phoneno for hash object
ERROR: DATA STEP Component Object failure. Aborted during the EXECUTION phase.

what does this even mean? what do I need to change to sort this? sorry I'm very new to hash tables

Hash Tables

astha8882000 — Wed, 11 Jul 2018 18:57:22 GMT

I have never used hash before, saw this piece of code being included in many places within a big project, can someone please help explain what each line means?

IF _n_ = 1 THEN DO;
Dcl Hash hh (dataset: 'work.CCEM');
hh.DefineKey ('tel);
hh.DefineDone ();
End;

Re: Hash Tables

Kurt_Bremser — Wed, 11 Jul 2018 19:03:42 GMT

It declares a hash object with one variable that acts as key. The object is populated from column tel in dataset work.ccem.

Re: Hash Tables

novinosrin — Wed, 11 Jul 2018 19:05:39 GMT

1. instantiate a hash object as soon as datastep loops past the data statement (_n_=1)

2. load the hash object with data by reading dataset work.CCEM

3. complete the instantiation with definedone

Re: Hash Tables

astha8882000 — Wed, 11 Jul 2018 19:07:42 GMT

Thank you.

Re: Hash Tables

FreelanceReinh — Wed, 11 Jul 2018 20:19:40 GMT

Just to add: Hash object hh will contain both a data item and a key item corresponding to variable tel, because the DefineData method is not used. (Or better: "would contain", if the closing single quote after "tel" wasn't missing.)

If you are an experienced data step programmer, I recommend that you familiarize yourself with the hash object. It's a really useful tool.

Re: Hash Tables

astha8882000 — Thu, 12 Jul 2018 13:15:23 GMT

If I could add a follow up to this:

I have a dataset created 'abc' in a sasgrid location

I'm creating another dataset 'xyz' through that using hash table, for eg.,

data xyz;

if _n_=1 then do;

dcl hash hh (dataset: 'abc');

hh.definekey ('phoneno');

hh.definedone();

end;

followed by a bunch of keep statements

run;

when I try and run this, I get the following 2 errors:

ERROR: Undeclared key symbol phoneno for hash object
ERROR: DATA STEP Component Object failure. Aborted during the EXECUTION phase.

what does this even mean? what do I need to change to sort this? sorry I'm very new to hash tables

Re: Using hash tables

astha8882000 — Thu, 12 Jul 2018 13:21:35 GMT

Instead of going that entire route, can I do a normal read from the dataset using

data xyz;

set abc;

keep ....

run;

but I was wondering why did whoever wrote the code (he left the company) add in the hash table anyway? what purpose was that serving?

Re: Hash Tables

Kurt_Bremser — Thu, 12 Jul 2018 13:26:36 GMT

You need to set phoneno to a value so that the find() method works:

data abc;
input phoneno $;
cards;
1234567
;
run;

data xyz;
if _n_=1 then do;
  dcl hash hh (dataset: 'abc');
  hh.definekey ('phoneno');
  hh.definedone();
end;
*phoneno = '1234567';
found = hh.find();
run;

Run that code, and you'll get your ERROR. Remove the comment asterisk, and it'll be OK.

Re: Using hash tables

SuryaKiran — Thu, 12 Jul 2018 13:27:59 GMT

If you don't have the phoneno variable in your 'abc' dataset then you will get this type of error. Make sure that variable is present in the dataset.

Re: Hash Tables

Kurt_Bremser — Thu, 12 Jul 2018 13:30:24 GMT

PS if you do this:

data xyz;
length phoneno $8;
if _n_=1 then do;
  dcl hash hh (dataset: 'abc');
  hh.definekey ('phoneno');
  hh.definedone();
end;
found = hh.find();
run;

there's no ERROR, but you won't find anything, as the empty string is not present as a key in the hash.

If your reference variable is present in another dataset, it will also work:

data def;
input phoneno $;
cards;
1234567
9865443
;
run;

data xyz;
set def;
if _n_=1 then do;
  dcl hash hh (dataset: 'abc');
  hh.definekey ('phoneno');
  hh.definedone();
end;
found = hh.find();
run;

Re: Using hash tables

PeterClemmensen — Thu, 12 Jul 2018 13:42:30 GMT

Run a PROC CONTENTS step like this

proc contents data=abc;
run;

and verify that the variable phoneno is present in the data set abc.

Also, if the DO Group is only followed by a bunch of Keep Statements and the hash object hh is not used, simply remove the entire do group. No reason for him to have left it there.

Re: Using hash tables

astha8882000 — Thu, 12 Jul 2018 13:48:56 GMT

I just checked, that variable is present in that dataset

Re: Using hash tables

Kurt_Bremser — Thu, 12 Jul 2018 13:51:03 GMT

This is obviously a continuation of https://communities.sas.com/t5/Base-SAS-Programming/Hash-Tables/m-p/477201.

Should I merge the threads?

Re: Using hash tables

astha8882000 — Thu, 12 Jul 2018 13:51:59 GMT

the only place that hh is used later is this condition:
%include inclf(f1.sas)
if hh.find()=0;
%include inclf(f2.sas)

what does this condition mean so I could replace this too and get rid of hh altogether?

Re: Using hash tables

PeterClemmensen — Thu, 12 Jul 2018 13:53:35 GMT

Then it is because phoneno is not present in the PDV for the xyz data set. Add an appropriate length statement or an if 0 then set abc like this

data abc;
phoneno=123;
run;

data xyz;
if 0 then set abc;
if _n_=1 then do;
   dcl hash hh(dataset: 'abc');
   hh.definekey('phoneno');
   hh.definedone();
end;
run;

Or.. Simply remove the entire do group with the hash declaration if it does not serve a purpose.

Re: Using hash tables

novinosrin — Thu, 12 Jul 2018 13:54:26 GMT

@astha8882000 Good morning and very good question. This raises the challenges of how sas compiles a hash object before execution phase starts.

Even if you do have the phoneno variable in your dataset 'abc'. you would still get that error. That's because hash object dot notation aren't compiled like the traditional variables in PDV when read from a sas dataset.

Assuming you have phoneno variable, the simple fix is:

data xyz;

if _n_=1 then do;

if 0 then set abc; /*notice this statement forcing sas to compile variables in the hash obj*/

dcl hash hh (dataset: 'abc');

hh.definekey ('phoneno');

hh.definedone();

end;

run;

Try to run with and without the above statement in bold, and see the log. You will notice the difference

Re: Using hash tables

Kurt_Bremser — Thu, 12 Jul 2018 13:57:45 GMT

@astha8882000 wrote:
the only place that hh is used later is this condition:
%include inclf(f1.sas)
if hh.find()=0;
%include inclf(f2.sas)

what does this condition mean so I could replace this too and get rid of hh altogether?

You need to have a variable phoneno present (from any source) in your datastep, so that the find() method has a reference.

The

ERROR: Undeclared key symbol phoneno for hash object

happens ONLY when the variable is not there, period. Run the codes I gave you in the other thread for verifying this.

PS to be more specific: the presence of phoneno in the dataset used to create the hash DOES NOT create a datastep variable phoneno. That has to come from another source, eg another dataset.

Re: Using hash tables

astha8882000 — Thu, 12 Jul 2018 14:01:35 GMT

Sure, thank you! I wasn't sure how to do that.

Re: Using hash tables

astha8882000 — Thu, 12 Jul 2018 14:07:05 GMT

Is there a way to get rid of hash tables altogether? The only place that it is used later in the code is this:

%include inclf(f1.sas)
if hh.find()=0;
%include inclf(f2.sas)

does this condition mean if there are no records in hh, which means if it read no records from dataset abc, only then the include f2 is run else not? If I could replace this too and get rid of hh altogether?

So for the initial part of the code I could just read the dataset abc into xyz using data and set steps like I would normally do, do you think that might work?