topic Re: Proc Report -Want to see a field two times-with format and without in SAS Programming

Proc Report -Want to see a field two times-with format and without

Ronein — Wed, 11 Jul 2018 09:57:24 GMT

 Data tbl;
 input branch sales;
 cards;
 1  10
 2  20
 3  30
 4  40
 ;
 run;


 proc format;
value FFMT 
1='North'
2='South'
3='East'
4='West';
Run;


Data tbl2;
set tbl;
FORMAT branch FFMT.;
Run;


proc report data=tbl2  headline split='#' spacing=1 nowd
style(report)={cellpadding=1 cellspacing=1}
style(header)={font_size=2  font_weight=MEDIUM  font_face=david  background=cx99ccaa}
style(column)={font_size=1}; 
columns  branch sales;
define branch/ display 
	"Branch"  center;
define sales/  order order=internal descending
	"SALES 2018";
Run;

Hello

I want that in the proc report field branch will appear 2 times: In one column as a formatted value (south,north,east,west)

In second column as a non formatted value( 1,2,3,4)

Re: Proc Report -Want to see a field two times-with format and without

MichaelLarsen — Wed, 11 Jul 2018 10:21:16 GMT

Try this:

proc report data=tbl2  headline split='#' spacing=1 nowd
style(report)={cellpadding=1 cellspacing=1}
style(header)={font_size=2  font_weight=MEDIUM  font_face=david  background=cx99ccaa}
style(column)={font_size=1}; 
columns  branch branch=branch2 sales;
define branch/ display 
	"Branch"  center;
define branch2/ display 
	"Branch unformatted" format=best. center;
define sales/  order order=internal descending
	"SALES 2018";
Run;

Regards,

Michael

Re: Proc Report -Want to see a field two times-with format and without

gamotte — Wed, 11 Jul 2018 10:23:46 GMT

Hello,

Data tbl;
 input branch sales;
 cards;
 1  10
 2  20
 3  30
 4  40
 ;
 run;


 proc format;
value FFMT 
1='North'
2='South'
3='East'
4='West';
Run;

proc report data=tbl  headline split='#' spacing=1 nowd
style(report)={cellpadding=1 cellspacing=1}
style(header)={font_size=2  font_weight=MEDIUM  font_face=david  background=cx99ccaa}
style(column)={font_size=1}; 
columns  branch branch2 sales;
define branch/ display 
	"Branch"  center;
define branch2 / computed format=FFMT.;
define sales/  order order=internal descending
	"SALES 2018";
compute branch2;
	branch2=branch;
endcomp;
Run;