topic Re: read raw data in SAS Programming

read raw data

AlexeyS — Thu, 05 Jul 2018 08:34:13 GMT

data cars;
INFILE DATALINES dlm=',';
input Make : $9. Invoice : comma6.;
datalines;
BMW,35,681
Chevrolet,28,197
;
run;

Why I can't read Invoice correctly? What's wrong?

Thank you

Re: read raw data

PeterClemmensen — Thu, 05 Jul 2018 07:55:31 GMT

You are using a comma both as a delimiter and as a digit separator in your data. Not a good idea. You could do something like this

data cars;
INFILE DATALINES dlm='|';
input Make : $9. Invoice : comma6.3;
datalines;
BMW|33,890
Chevrolet|17,234
Ford|14,482
Infinity|27,536
;
run;

Re: read raw data

Kurt_Bremser — Thu, 05 Jul 2018 08:05:26 GMT

It contains a delimiter. Delimiters take precedence over commas used as a decimal point.

Use a different delimiter or "mask" the commas with quotes and the dsd option:

data cars;
INFILE DATALINES dlm=',' dsd;
input Make : $9. Invoice : comma6.;
datalines;
BMW,"33,890"
Chevrolet,"17,234"
Ford,"14,482"
Infinity,"27,536"
;
run;

Re: read raw data

AlexeyS — Thu, 05 Jul 2018 08:16:13 GMT

You want to say, that i cannot read a raw data as i wrote?

Why i ask, because i saw a lot of palces, where they write it as me, but it doen't work.

for example, https://onlinecourses.science.psu.edu/stat481/node/60/

Re: read raw data

Kurt_Bremser — Thu, 05 Jul 2018 08:30:21 GMT

In that example page, they never use a comma as delimiter.

Re: read raw data

AlexeyS — Thu, 05 Jul 2018 08:34:53 GMT

you are right, excuse me

Re: read raw data

Tom — Thu, 05 Jul 2018 13:14:39 GMT

If the field with the embedded delimiter is the last one in the line then just read that field using formatted input instead of list mode input. Just remove the colon modifier before the format specification in the INPUT statement.

data cars;
  INFILE DATALINES dlm=',' dsd truncover;
  input Make  :$9. Invoice comma6.;
datalines;
BMW,35,681
Chevrolet,28,197
;

If the field is in the middle of the line then you will need to work harder to figure out which parts belong to which fields.