topic Re: Date data in SAS Programming

Date data

Ronein — Sun, 24 Jun 2018 09:57:24 GMT

Hello

In Example1 I enter a date data as a character

Data Example1;
input ID 1
Loan_ID 3
Sum_Loan 5-7
Interest 9-11
date_Loan $ 13-22 ;
Cards;
1 1 100 2.4 01/06/2018
;
run;

In Example2 I am trying to enter a date data as sas numeric and I get empty values.Why????

Data Example2;
input ID 1
Loan_ID 3
Sum_Loan 5-7
Interest 9-11
date_Loan 13-22 ;
Cards;
1 1 100 2.4 01/06/2018
;
run;

Re: Date data

Kurt_Bremser — Sun, 24 Jun 2018 10:36:56 GMT

SAS does not automatically recognize a date (or a time value) as such, so you need to give it an informat:

data  example2;
input
  ID
  Loan_ID
  Sum_Loan
  Interest
  date_Loan :ddmmyy10.
;
format date ddmmyy10.;
cards;
1 1 100 2.4 01/06/2018
;
run;

Re: Date data

Tom — Sun, 24 Jun 2018 23:19:52 GMT

If you want SAS to read '01/06/2018' as the first of june 2018 then use the DDMMYY informat. If instead you want it to treat that as the sixth of January then use the MMDDYY informat. Either way make sure to attach a format so that SAS doesn't display the date as the raw number of days since the beginning of 1960.

data Example1;
  input
    ID 1
    Loan_ID 3
    Sum_Loan 5-7
    Interest 9-11
    @13 date_mdy mmddyy10.
    @13 date_dmy ddmmyy10.
  ;
  format date: date9. ;
cards;
1 1 100 2.4 01/06/2018
;

In future it might be best to store your date strings in either Year, Month, Day order or use SAS's DATE format and avoid the confusion.