topic Re: how to extract perticular word. in SAS Programming

how to extract perticular word.

kuridisanjeev — Wed, 04 Apr 2012 13:58:05 GMT

NUMBER	TEXT
1	1.YOUR NAME IS 'SANJEEV.'
2	2.YOUR NAME IS 'SRINATH.'

From Above data , i want to make some changes in text variable.

i want to exclude the numering in each text.

for example i want to display the text column like this YOUR NAME IS 'SAJEEV.'(remove 1.)

Please advise Me..

Thanks..

Re: how to extract perticular word.

Haikuo — Wed, 04 Apr 2012 14:04:09 GMT

Try this:

data have;

input number text&$30.;

cards;

1 1.YOUR NAME IS 'SANJEEV.'

2 2.YOUR NAME IS 'SRINATH.'

;

data want;

set have;

text=compress(text,'.','d');

proc print;run;

Haikuo

how to extract perticular word.

kuridisanjeev — Wed, 04 Apr 2012 14:05:50 GMT

What is the Use of d??

how to extract perticular word.

Haikuo — Wed, 04 Apr 2012 14:08:59 GMT

'd' denotes 'digits', which tells compress() to get rid of any digits. Compress() is far more powerful than it looks at the first sight.

Re: how to extract perticular word.

kuridisanjeev — Wed, 04 Apr 2012 14:13:31 GMT

if you use ' . ' in compress function,all the dot's is going to be deleted.

but i want to retain the dot's after Sanjeev and SRINATH words.

Re: how to extract perticular word.

Astounding — Wed, 04 Apr 2012 14:22:03 GMT

It's a little messy, but it can be crammed into one statement:

text = substr(text, length(scan(text, 1, '.'))+2);

This assumes that every observation needs to remove something from the beginning of TEXT, so that IF/THEN is not required.

Good luck.

Edited:

Actually, this is a little safer (as well as simpler) in case there is are spaces between the number and the dot:

text = substr(text, index(text, '.') +1);

how to extract perticular word.

kuridisanjeev — Wed, 04 Apr 2012 14:32:51 GMT

sorry i didn't get you..

for 2nd observation,substr works like this..

scan(text,1,'.') value is 2.

text=substr(text,2+2)

which means text=substr(text,4).

So i think above logic not suitable for my requirement...

Correct me if i did any thing wrong..

Thank you..

Re: how to extract perticular word.

Astounding — Wed, 04 Apr 2012 14:36:23 GMT

See my revised approach, for a simpler, better way. But note that the original approach should have generated the equivalent of:

text = substr(text, length("2") +2)

Good luck.

Re: how to extract perticular word.

Haikuo — Wed, 04 Apr 2012 14:44:30 GMT

All right, then compress() can't help you on this case. The last resort would be allmighty prx:

data have;

input number text&$30.;

cards;

1 1.YOUR NAME IS 'SANJEEV.'

2 2.YOUR NAME IS 'SRINATH.'

1132 1132.YOUR NAME IS 'SANJEEV.'

23 23.YOUR NAME IS 'SRINATH.'

;

data want;

set have;

text=prxchange('s/\d+\.//',1,text);

proc print;run;

Haikuo

Edit: The reason I am not big fan of prx is that they are easy to WRITE, but impossible to READ. However, it seems that there is nothing they can't do in term of string manipulation, I have updated raw data to show its' power.

Re: how to extract perticular word.

kuridisanjeev — Wed, 04 Apr 2012 14:44:47 GMT

I think after length function we need add ',' right????

Re: how to extract perticular word.

Astounding — Wed, 04 Apr 2012 14:47:30 GMT

No, no comma. The idea is that we'll specify just 2 arguments to SUBSTR. When the third argument is omitted, SUBSTR will take all remaining characters. So we really need to compute the second argument, telling SUBSTR where to begin.

Re: how to extract perticular word.

Haikuo — Wed, 04 Apr 2012 14:57:45 GMT

It would be a little less brain-twisting if we just first to use compress() to get rid of the digits and then substr from the second char.

data have;

input number text&$30.;

cards;

1 1.YOUR NAME IS 'SANJEEV.'

2 2.YOUR NAME IS 'SRINATH.'

1132 1132.YOUR NAME IS 'SANJEEV.'

23 23.YOUR NAME IS 'SRINATH.'

;

data want;

set have;

text=substr(compress(text,,'d'),2);

proc print;run;

Regards,

Haikuo

Re: how to extract perticular word.

kuridisanjeev — Wed, 04 Apr 2012 14:58:05 GMT

oh sorry.

i made some wrong assumptions while understanding the logic..

Now i got it..

Thank you very much...

Re: how to extract perticular word.

Astounding — Wed, 04 Apr 2012 15:02:42 GMT

Hai.kuo,

Yes, if you are willing to rely on removing all digits. You wouldn't want to encounter:

25.YOUR NAME IS 'R2D2.'

Re: how to extract perticular word.

Haikuo — Wed, 04 Apr 2012 15:08:08 GMT

LOL. I have to agree. Even I have never seen a human name embeded with number (inmates id not included), but like John Maccain just said, 'if you live long enough, anything can happen'.

Haikuo

Re: how to extract perticular word.

JatinBansal — Fri, 20 Dec 2013 10:31:24 GMT

I think following is the simplest thing we can do to get the required:

data new;

input text $50.;

datalines;

1.YOUR NAME IS 'SANJEEV.'

2.YOUR NAME IS 'SRINATH.'

333.Your name is anything.

;

data this;

set new;

text2 = substr(text, find(text,'.')+1);

run;

Re: how to extract perticular word.

KarthikSrivasthav — Fri, 20 Dec 2013 12:44:32 GMT

Which word u want in the above example

Re: how to extract perticular word.

Peter_C — Sat, 21 Dec 2013 12:20:16 GMT

I would use verify() to locate the first character of the name like

namepart = substr( text, verify( text, '0123456789 .' ));

Re: how to extract perticular word.

yaswanthj — Mon, 23 Dec 2013 11:19:39 GMT

Hi Sanjeev,

This code may will help you..

data have;

input number text&$30.;

cards;

1 1.YOUR NAME IS 'SANJEEV.'

2 2.YOUR NAME IS 'SRINATH.'

;

run;

proc print;

run;

data want;

set have;

/*text=compress(text,'.','d');*/

text =substr(strip(text),indexc(text ,'.')+1,length(text )-indexc(text ,'.'));

proc print;run;

Thanks,

Yaswanth J.