topic Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code in SAS Programming

Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Linlin — Wed, 04 Apr 2012 13:27:16 GMT

Hi All,

How can I get the same result without the data step “data have; set have; if _n_>1; run;”?

Thanks - Linlin

data have;

input (ABC F1 F2 FDG)($);

cards;

ID Name Sex Country

1 ABC M IND

2 BCD F USA

3 CDE M GER

4 DGE M UK

;

proc transpose data=have(obs=1) out=temp;

var _all_;

run;

proc sql ;

select catx('=',_name_,col1)

into :rename separated by ' '

from temp;

quit;

/* please help me to get rid of this data step */

data have; set have; if _n_>1; run;

proc datasets nolist lib=work;

modify have ;

rename &rename;

run;

quit;

proc print data=have;run;

Obs ID Name Sex Country

1 1 ABC M IND

2 2 BCD F USA

3 3 CDE M GER

4 4 DGE M UK

Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Astounding — Wed, 04 Apr 2012 13:40:36 GMT

Linlin,

I think the simplest approach would be to create 2 data sets instead of 1 originally:

data have1 have2;

input ...;

if _n_=1 then output have1;

else output have2;

cards;

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Linlin — Wed, 04 Apr 2012 13:54:17 GMT

Hi Astounding,

I need to let you know that I am your sister, not your brother.:smileylaugh:

Thank you. I should not use proc datasets at all.

data have;

input (ABC F1 F2 FDG)($);

cards;

ID Name Sex Country

1 ABC M IND

2 BCD F USA

3 CDE M GER

4 DGE M UK

;

proc transpose data=have(obs=1) out=temp;

var _all_;

run;

proc sql ;

select catx('=',_name_,col1)

into :rename separated by ' '

from temp;

quit;

data have;

set have(firstobs=2 rename=(&rename));

run;

proc print;run;

updated after Astounding's comments. Thank you!

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Haikuo — Wed, 04 Apr 2012 13:59:36 GMT

Not exactly what you want, but can save some of your typing. However, it still requires one pass of datastep, so it would not boost efficiency much.

data have;

input (ABC F1 F2 FDG)($);

cards;

ID Name Sex Country

1 ABC M IND

2 BCD F USA

3 CDE M GER

4 DGE M UK

;

proc transpose data=have(obs=1) out=temp;

var _all_;

run;

proc sql ;

select catx('=',_name_,col1)

into :rename separated by ' '

from temp;

quit;

data have (rename=(&rename)); set have; if _n_>1; run;

proc print data=have;run;

Edit: Oooooooooops

Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Astounding — Wed, 04 Apr 2012 14:02:17 GMT

Sister,

If you're willing to go with the DATA step, here's a slight improvement:

data have (rename=(&rename));

set have (firstobs=2);

run;

Good luck.

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Linlin — Wed, 04 Apr 2012 14:07:28 GMT

Hi Haikuo,

This definitely show that we are excellent students of Art, Tom, and Ksharp! - Linlin

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Haikuo — Wed, 04 Apr 2012 14:11:56 GMT

Can't agree more!

BTW, Ksharp is in between jobs, so he maynot have a reliable access to SAS for the time being. Maybe that is why we haven't seen him much for the past a few days.

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

FriedEgg — Wed, 04 Apr 2012 15:42:30 GMT

One step solution:

%let input=abc f1 f2 fdg;

%let vinput="%sysfunc(prxchange(s/\x20/%str(" ")/,-1,&input))";

data have(rename=(&rename));

input (&input) ($);

array _v[4] &input;

if _n_=1 then do;

array _s[4] $ (&vinput);

length _x $ 100;

do _n=1 to dim(_s);

_r=catx('=',_s[_n],_v[_n]);

_x=catx(' ',_x,_r);

end;

call symputx('rename',_x);

end;

else output;

drop _:;

cards;

ID Name Sex Country

1 ABC M IND

2 BCD F USA

3 CDE M GER

4 DGE M UK

;

proc print noobs;

run;

ID	Name	Sex	Country
1	ABC	M	IND
2	BCD	F	USA
3	CDE	M	GER
4	DGE	M	UK

P.S. KSharp/others if you happen to read this check out my profile status for a link to two jobs I am currently hiring for (in the USA though)

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

PGStats — Wed, 04 Apr 2012 15:53:03 GMT

Or everything can be done in SQL :

data have;
input (ABC F1 F2 FDG)($);
cards;
ID Name Sex Country
1 ABC M IND
2 BCD F USA
3 CDE M GER
4 DGE M UK
;

proc sql noprint;

select name into :names separated by ','
from dictionary.columns
where libname="WORK" and memname="HAVE";

select catx(" ",&names.) into :vals
from have(obs=1);

select catx(" AS ", name, scan("&vals.", varnum)) into :cmd separated by ','
from dictionary.columns
where libname="WORK" and memname="HAVE";

reset nowarnrecurs;
create table have as
select &cmd. from have(firstobs=2);

quit;

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Linlin — Thu, 05 Apr 2012 19:50:28 GMT

Hi FE and PG,

Thank you for your reply! it is very enjoyable for me to go through all the interesting solutions! - Linlin

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

chang_y_chung_hotmail_com — Thu, 05 Apr 2012 22:20:00 GMT

I would prefer running a proc datasets to running a whole data step just to rename variables. In any case, the key here is to generate the rename list automatically. Here is another way. Just make sure that you give long enough length in the initial value of the retained variable in the data _null_ step. hope this helps a bit.

data names have;
   input (a b c d) (:$8.);
   if _n_ = 1 then output names;
   else output have;
cards;
ID Name Sex Country
1 ABC M IND
2 BCD F USA
3 CDE M GER
4 DGE M UK
;
run;

proc transpose data=names
   out=names(rename=(_name_=old col1=new));
   var _all_;
run;

data _null_;
   retain rename "%sysfunc(repeat(%str( ), 80))";
   set names end=end;
   rename = catx(" ", rename, catx("=", old, new));
   if end then call symputx("rename", rename);
run;

%put rename=***&rename***;

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

MikeZdeb — Fri, 06 Apr 2012 01:57:52 GMT

hi .. another idea ...

data have;

input (ABC F1 F2 FDG)($);

cards;

ID Name Sex Country

1 ABC M IND

2 BCD F USA

3 CDE M GER

4 DGE M UK

;

filename nosee dummy;

data _null_;

file nosee;

set have (obs=1);

put (_all_) (=) @;

call symputx('rename',_file_);

run;

data have;

set have (firstobs=2 rename=(&rename));

run;

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

PGStats — Fri, 06 Apr 2012 02:15:54 GMT

Wow! That is mighty clever.

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

MikeZdeb — Fri, 06 Apr 2012 02:46:25 GMT

hi ... among the many things I have learned from Howard Schreier is neat stuff you can do with _FILE_ ...

http://www.listserv.uga.edu/cgi-bin/wa?A2=ind0811b&L=sas-l&P=23589

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Linlin — Fri, 06 Apr 2012 03:38:47 GMT

Hi Mike,

Thank you! I tried to help this OP to find a better solution: https://communities.sas.com/thread/34279

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Ksharp — Fri, 06 Apr 2012 09:23:39 GMT

Matt,

I have send you an E-mail. Check it out.

Ksharp

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Ksharp — Fri, 06 Apr 2012 09:31:44 GMT

Thank you HaiKuo and Linlin, to mention me .

I am very frustrated .

It is very hard to find a job about SAS Programmer in China. I don't know where to go.

SAS is not popular in China. Maybe I pick up a wrong-direction job, Now I have been studying Java for a few monthes.

Ksharp

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

Linlin — Fri, 06 Apr 2012 10:46:47 GMT

Hi Ksharp,

You are so good with SAS, I think SAS should offer you a job. Thank you very much for helping all of us!

Re: Please help me to get rid of the data step “data have; set have; if _n_>1; run;” in my code

FriedEgg — Fri, 06 Apr 2012 17:41:34 GMT

chang_y_chung@hotmail.com

I like your method of length initialization for the retain statement instead of using the length statement. Very nice.