topic Re: Replace string with another string in SAS Programming

Replace string with another string

s_manoj — Tue, 29 May 2018 08:16:37 GMT

Hi all,

I have a sentence like "I am a student in a college in a city in India to study masters"

in the above sentence, I want to replace the second occurrence of "in" with "from".

Can anyone suggest me code to replace it.

i have tried with the following code, i made it. But am looking for another way which makes easy to execute.

data x;

word = "I am a student in a college in a city in India to study masters";

substr(word, 29, 2) = "from";

run;

Thank you & regards.

Manoj

Re: Replace string with another string

s_lassen — Tue, 29 May 2018 08:21:10 GMT

You probably want to use the TRANWRD function:

Word=tranwrd(Word,'to','from');

Re: Replace string with another string

s_manoj — Tue, 29 May 2018 09:30:31 GMT

Thank you for replay,

by using TRANWRD all in 's will be replaced by "from", but i want to replace only second "in" with "from"

Re: Replace string with another string

RW9 — Tue, 29 May 2018 10:23:47 GMT

And what is the logic to assume that? Simply put, if you had the string:

I am a student in a college in a city in India to study masters

How are we to note that the second in is to be replaced, and not the others?

I mean I could tell you to substr or scan the string, but that would only help in this one specific case.

Re: Replace string with another string

ChrisNZ — Tue, 29 May 2018 10:35:47 GMT

Like this?

NEWWORD=prxchange('s/(.*? in .*?)( in )(.*)/$1 from $3/',-1,WORD);

I hope there's no error, I can't test atm.

Re: Replace string with another string

Ksharp — Tue, 29 May 2018 13:45:35 GMT

data x;
word = "I am a student in a college in a city in India to study masters    ";
put word= ;

pid=prxparse('/\bin\b/i');
s=1;e=length(word);
call prxnext(pid,s,e,word,p,l);
n=0;
do while(p>0);
 n+1;
 if n=2 then do;want=substr(word,1,p-1)||'from'||substr(word,p+l);leave;end;
 call prxnext(pid,s,e,word,p,l);
end;
put want= ;
run;

Re: Replace string with another string

Haikuo — Tue, 29 May 2018 13:28:12 GMT

You already have your answer, both answers from @ChrisNZ and @Ksharp should work. I am here just to comment that your original example code will not work for your purpose. The reason being SAS using FIXED length variable, you will need byte abundancy or some walk-around (rename etc.) to replace with a longer chars, notice @Ksharp's example with some blanks padded.

Re: Replace string with another string

mahesh146 — Tue, 29 May 2018 14:15:04 GMT

DATA TEMP;
word = "I am a student in a college in a city in INDIA to study masters";

word_len= LENGTH(STRIP(word));
fst_pos= FINDW(STRIP(word),'in');
snd_pos= FINDW(STRIP(word),'in',fst_pos+1);

new_str_part1= substr(STRIP(word),1,snd_pos-1);
new_str_part2= 'from';
new_str_part3= substr(STRIP(word),snd_pos+2);

new_word= CAT(new_str_part1,new_str_part2,new_str_part3);

DROP word_len fst_pos snd_pos new_str_part:;
run;

PROC PRINT DATA=TEMP;
RUN;

Re: Replace string with another string

s_manoj — Wed, 30 May 2018 07:09:52 GMT

Thank you, this one worked

Re: Replace string with another string

s_manoj — Wed, 30 May 2018 07:10:15 GMT

Thank you this one worked

Re: Replace string with another string

Ksharp — Wed, 30 May 2018 14:01:07 GMT

@ChrisNZ

Can you explain the red one stand for what ?

prxchange('s/(.*? in .*?)( in )(.*)/