topic Re: Replace a Space with a Dash in SAS Programming

Replace a Space with a Dash

Lost_Gary — Mon, 21 May 2018 20:27:49 GMT

This might be easy, but I keep getting hung up on this. I am trying to replace a space with a dash within an address field. For instance, the address is listed as 12 345 main street. I am trying to get it to add a dash, but only in the first space i.e. 12-345 main street.

I appreciate the assistance.

Re: Replace a Space with a Dash

novinosrin — Mon, 21 May 2018 20:31:26 GMT

 
data w;
k='12 345 main street.';
substr(k,index(k,' '),1)='-';
run;

Re: Replace a Space with a Dash

Lost_Gary — Mon, 21 May 2018 20:58:20 GMT

Brilliant. Thank you.

Re: Replace a Space with a Dash

art297 — Mon, 21 May 2018 21:14:23 GMT

While you've marked this question as solved, unless all of your addresses have that pattern of numbers, I think you will be exchanging a number of spaces for hyphens where you don't really want to.

I'd suggest using pattern matching. E.g.,

data have;
  address='12 345 main street.';
  output;
  address='345 main street.';
  output;
run;

data want;
  set have;
  address = prxchange('s/(\d+) (\d+)/$1-$2/', -1, address);
run;

Art, CEO, AnalystFinder.com

Re: Replace a Space with a Dash

Lost_Gary — Mon, 21 May 2018 23:33:51 GMT

ooh, I like the efficiency in that coding and also learning different ways. So a thumbs up for this method as well.

The problem with addresses that I am finding, is the scenario of the address '345 1st avenue' as '345-1st avenue' would be inaccurate (for this scenario). So, my less than efficient solution was to create different 'rules' to isolate the scenarios in which the 'substr' function works better to replace some of the spaces. I know what i am doing isn't perfect.

Re: Replace a Space with a Dash

art297 — Tue, 22 May 2018 00:09:06 GMT

Precisely why I suggested using pattern matching. That one is easy to correct:

data have;
  address='12 345 main street.';
  output;
  address='345 main street.';
  output;
  address='345 1st avenue';
  output;
run;

data want;
  set have;
  address = prxchange('s/(\d+) (\d+) /$1-$2 /', -1, address);
run;

Art, CEO, AnalystFinder.com