topic Re: how do I get the value of a variable via its name in SAS Programming

how do I get the value of a variable via its name

acordes — Wed, 25 Apr 2018 19:44:50 GMT

If a condition is met, I want to call missing of a set of variables whose members depend on the condition as well.

My hard coded program works but I cannot automate it.

DATA TEST;

ARRAY X [4] $3 ('ANT' 'BEE' 'CAT' 'DOG'); 
N=DIM(X);
DO U=1 TO N-1;
NCOMB=COMB(N,U ); 
DO I=1 TO NCOMB;   

CALL LEXCOMB(I, U, OF X[*]);
OUTPUT;
END;
END;
NFACT=FACT(N);
DO J=1 TO NFACT;
CALL ALLPERM(J,OF X[*]);
OUTPUT;
END;
RUN;

DATA TEST2;
SET TEST;

IF U=1 THEN CALL MISSING (OF X2-X4);
IF U=2 THEN CALL MISSING (OF %SYSFUNC(CATT(X3-,X,%EVAL(3+1)))); 
IF U=3 THEN CALL MISSING (X4);
HELP=VVALUEX(CATT("X",%SYSFUNC(SUM(3,1))));

RUN;

The CALL MISSING part does not accept in the %eval bracket the numeric variable but complains that a char var is passed.

Thanks

Re: how do I get the value of a variable via its name

Astounding — Wed, 25 Apr 2018 20:06:13 GMT

The DATA step cannot use CAT functions to generate the code that is part of the same DATA step. A simpler version would overcome the initial problem:

IF U=2 THEN CALL MISSING (OF X3-X%EVAL(3+1));

I'm not sure what you're trying to get into the HELP formula, but this might be a little closer:

help = X%eval(3+1);

The macro functions do not execute as the DATA step executes. They execute before the DATA step begins, and generate the statements that become part of the DATA step code.

Re: how do I get the value of a variable via its name

acordes — Wed, 25 Apr 2018 20:00:45 GMT

Thank you.

But it doesn´t work neither when putting

IF U=2 THEN CALL MISSING (OF X3-X%EVAL(U+1));

The code deosn't like the reference to the numeric variable U

Re: how do I get the value of a variable via its name

Astounding — Wed, 25 Apr 2018 20:10:18 GMT

You're right, it definitely doesn't work for that. DATA step statements cannot change from one observation to the next. Whatever the statement is, it remains the same for all observations. You might need a loop, more like:

array x {*} X: ;

do k=3 to u+1;

call missing (x{k});

end;

Re: how do I get the value of a variable via its name

acordes — Wed, 25 Apr 2018 20:19:44 GMT

Perfect. Thanks.
If you have an idea to achieve my goal within the first permutation generating data set... Feel free to excel

Re: how do I get the value of a variable via its name

acordes — Thu, 26 Apr 2018 08:07:26 GMT

It has worked out. Thank you again.

The final code is:

DATA TEST;

ARRAY X [4] $3 ('ANT' 'BEE' 'CAT' 'DOG'); 
N=DIM(X);
DO U=1 TO N-1;
NCOMB=COMB(N,U ); 
DO I=1 TO NCOMB;   

CALL LEXCOMB(I, U, OF X[*]);
OUTPUT;
END;
END;
NFACT=FACT(N);
DO J=1 TO NFACT;
CALL ALLPERM(J,OF X[*]);
OUTPUT;
END;
RUN;

DATA TEST2;
SET TEST;
ARRAY X{*} X:;

DO K=2 TO DIM(X);
IF U LT K THEN CALL MISSING (X{K});
END;

HELP=VVALUEX(CATT("X",%SYSFUNC(SUM(3,1))));

RUN;

Re: how do I get the value of a variable via its name

jim_cai — Mon, 21 May 2018 11:05:59 GMT

Or you could generate the data set wih one Data Step only, although two sets of extra temporary variables are in need.

data test;
   array y[4] $3. _temporary_ ('ANT' 'BEE' 'CAT' 'DOG');
   array _x[4] $3.;
   array x[4] $3.;
   drop _:;
   n = dim(y);
   do i=1 to n;
      do j=1 to comb(n, i);
         if j=1 then do k=1 to n;
            _x[k] = y[k];
         end;
         call lexcomb(j, i, of _x[*]);
         do k=1 to i;
            x[k] = _x[k];
         end;
         output;
      end;
   end;
run;