topic Re: Data Saparation in SAS Programming

Data Saparation

Son_Of_Krypton — Mon, 30 Apr 2018 10:54:52 GMT

I have a table which contains both character and numeric values and I want character values in one table and numeric values in another table how to do this.??

Re: Data Saparation

PeterClemmensen — Mon, 30 Apr 2018 11:07:42 GMT

Do something like this

data have;
input Char1 $ Char2 $ Num1 Num2;
datalines;
ten twenty 10 20
thirty forty 30 40
fifty sixty 50 60
;

proc sql noprint;
    select name into :charVars separated by " " from dictionary.columns 
    where libname="WORK" and memtype="DATA" and memname="HAVE" and type="char";
    select name into :numVars separated by " " from dictionary.columns 
    where libname="WORK" and memtype="DATA" and memname="HAVE" and type="num";
quit;

%put &charVars.;
%put &numVars.;

data CharacterVars;
    set have;
    keep &charVars.;
run;

data NumericVars;
    set have;
    keep &numVars.;
run;

Re: Data Saparation

Son_Of_Krypton — Mon, 30 Apr 2018 11:18:56 GMT

can we do this in data step without using macros.??

Re: Data Saparation

Ksharp — Mon, 30 Apr 2018 11:28:40 GMT

data CharacterVars;
    set have;
    keep _numeric_;
run;

data NumericVars;
    set have;
    keep _character_;
run;

Re: Data Saparation

ChrisNZ — Mon, 30 Apr 2018 11:31:46 GMT

data N(keep=_NUMERIC_) 
     C(keep=_CHARACTER_);
  set SASHELP.CLASS;
run;

Re: Data Saparation

RW9 — Mon, 30 Apr 2018 12:02:56 GMT

Whilst you have the answer, I would ask why you want to do this? I suspect you want to do some procedure on just num vars or something like that, in which case you don't need to. You can use the automatic _numeric_ and _character_ to refere to either blocks pretty much anywhere, e.g.:

proc means data=have;
  var _numeric_;
run;

No need to split.

Re: Data Saparation

Son_Of_Krypton — Mon, 30 Apr 2018 12:04:07 GMT

Thanks for the solution