topic Re: Calculate percentage of total in SAS Programming

Calculate percentage of total

scb — Thu, 19 Apr 2018 11:00:46 GMT

I have the below dataset

data A;
Input CHANNEL $ AMOUNT ;
cards;
ABC 110
ABC 220
ABC 770
BBC 810
BBC 190
;
run;

May I know how to generate the below output with the above data? Thanks.

Channel Amount Percent

ABC 110 0.1

ABC 220 0.2

ABC 770 0.7

BBC 110 0.11

BBC 890 0.89

Re: SAS QUERY

RW9 — Thu, 19 Apr 2018 11:00:09 GMT

Proc means/summary/freq. Simple search on the SAS docs gives examples:

http://support.sas.com/kb/25/237.html

Re: Calculate percentage of total

DJongman — Thu, 19 Apr 2018 12:19:41 GMT

Hi scb,

As RW9 already stated in his post see the example link he provided.

But hereby a little bit of code to get you started:

Data A;
Input Channel $ Amount ;
cards;
ABC 110
ABC 220
ABC 770
BBC 810
BBC 190
;
run;

Proc SQL;                                                       
  Create Table B AS                                     
    Select *,(Amount/SUM(Amount)) AS Percent format=6.2      
  	From A                                             
	Group BY Channel;
Quit;

Re: Calculate percentage of total

Ksharp — Thu, 19 Apr 2018 12:21:43 GMT

data A;
Input CHANNEL $ AMOUNT ;
cards;
ABC 110
ABC 220
ABC 770
BBC 810
BBC 190
;
run;

proc sql;
select *,AMOUNT/sum(AMOUNT)  format=percent8.2
 from a as x
   group by CHANNEL;
quit;

Re: Calculate percentage of total

acordes — Thu, 19 Apr 2018 14:50:56 GMT

data A;
Input CHANNEL $ AMOUNT ;
cards;
ABC 110
ABC 220
ABC 770
BBC 810
BBC 190
;
run;

DATA A2;
SET A;
CHAR_AMOUNT=AMOUNT;
RUN;

PROC FORMAT;
PICTURE PCTPIC low-high='000.0%';
RUN;


TITLE;
PROC TABULATE DATA=WORK.A2 OUT=TEST ;
CLASS CHANNEL CHAR_AMOUNT;
KEYLABEL PCTSUM="% within Channel";
VAR amount;
TABLE CHANNEL*CHAR_AMOUNT, (amount*(SUM*F=6. PCTSUM<AMOUNT*CHAR_AMOUNT>*F=PCTPIC.)) / RTS=20;
RUN;

Re: Calculate percentage of total

sasuser123123 — Mon, 26 Aug 2019 11:51:51 GMT

And I've doubt ...
I've two variables TRT1,TRT2 those has values like 45(23%),55(56%) I want to add new variable total which should contains count and percentage like 100(79)... Can you please tell me how to create