topic Re: Assign a number with ind two groups based on date information in SAS Programming

Assign a number with ind two groups based on date information

Solvej — Wed, 11 Apr 2018 13:21:35 GMT

Dear Experts

I have the following data in the three first columns and would like to assign the number in column four (meeting number). The number is based on the date. If this shifts then a new number has to be assigned. The data set includes numerus other variables.

Record_id	Admission number	Date	Meeting number
1	1	01-01-2001	1
1	1	01-01-2001	1
1	1	01-03-2001	2
1	2	01-05-2001	1
1	2	01-05-2001	1
1	2	01-05-2001	1

Kind regards

Solvej

Re: Assign a number with ind two groups based on date information

Shmuel — Wed, 11 Apr 2018 13:49:12 GMT

Assuming data is sorted by the 3 coloms then do:

data want;
  set have;
       by record_id Admission_nomber date;
       retain meeting_number;

      if first.date then meeting_number = 1;
      else meeting_number +1;
run;

Re: Assign a number with ind two groups based on date information

Astounding — Wed, 11 Apr 2018 14:11:08 GMT

I think that's in the ballpark, but you need to tweak the logic a bit:

data want;
set have;
       by record_id Admission_number date;
      if first.admission_number then meeting_number = 1;
      else if first.date then meeting_number +1;
run;

Re: Assign a number with ind two groups based on date information

shantanupl1 — Wed, 11 Apr 2018 14:14:15 GMT

Hi,

Try this code.

data test;
set abc;
by record_id adm_no;
retain hold .;
if first.adm_no then do;
hold=date;
meeting=1;
end;
if hold ne date then do;
hold = date;
meeting + 1;
end;
run;

Re: Assign a number with ind two groups based on date information

Ksharp — Wed, 11 Apr 2018 14:25:27 GMT

data have;
infile cards expandtabs;
input Record_id	Admission 	Date : $20.;
cards;
1	1	01-01-2001	1
1	1	01-01-2001	1
1	1	01-03-2001	2
1	2	01-05-2001	1
1	2	01-05-2001	1
1	2	01-05-2001
;
run;
data want;
 set have;
 by Record_id	Admission	Date;
 if first.Admission then want=0;
 want+first.date;
run;

Re: Assign a number with ind two groups based on date information

novinosrin — Wed, 11 Apr 2018 14:50:03 GMT

data have;
infile cards expandtabs;
input Record_id	Admission 	Date : $20.;
cards;
1	1	01-01-2001	1
1	1	01-01-2001	1
1	1	01-03-2001	2
1	2	01-05-2001	1
1	2	01-05-2001	1
1	2	01-05-2001
;
run;


data want;
set have;
by record_id admission date;
k=lag(Date);
if first.Admission then meeting_number=1;
else if k ne date then meeting_number+1;
drop k;
run;