topic Re: Nesting macro definitions in SAS Programming

Nesting macro definitions

SAS_inquisitive — Fri, 06 Apr 2018 00:46:19 GMT

Hello:

I am looking for an example where inner macro definition gets the input from outer macro definition. Is this type of construction possible?


%macro outer;
   %global a
  
   %let a = 10;

	%macro inner;
		
		%if &a = 10 %then 
			%do;

		   .........

			%end;

	%mend inner;

%mend outer;

Re: Nesting macro definitions

Astounding — Fri, 06 Apr 2018 01:15:40 GMT

Macros can pass information to one another without nesting their definitions As a result, it is almost never good practice to nest macro definitions.

"Almost never" allows for this possibility. Should executing the %OUTER macro change the definition of the %INNER macro? It's not a question of whether information can be passed. That can always happen whether the definitions are nested or not. It's a question of whether running %OUTER should change the meaning of %INNER. That almost never happens.

Re: Nesting macro definitions

Reeza — Fri, 06 Apr 2018 01:49:17 GMT

@SAS_inquisitive wrote:

Hello:

I am looking for an example where inner macro definition gets the input from outer macro definition. Is this type of construction possible?

Possible does not mean you should. And you really really shouldn't do this. Please never do this. Ever.

Re: Nesting macro definitions

SAS_inquisitive — Fri, 06 Apr 2018 02:52:35 GMT

@Astounding. You got my point. I did not frame the question correctly. I meant to see how outer macro passes the information to the inner macro (not necessarily changing the meaning of inner macro).

Here is seemingly independent inner and outer macros. I want to see the correlation between them.


%macro outer;
	%global a;
	%let a = 10;

	%macro inner;
		%global b;
		%let b = 20;
	%mend inner;

	%inner;
%mend;

%outer;
%put &a &b;

Re: Nesting macro definitions

Tom — Fri, 06 Apr 2018 04:47:46 GMT

Macros are NOT nested, the list of macro names is a simple list, not a heirarchy. Nesting one macro's definition inside of another macro will not change that fact.

Macro EXECUTION can be nested.

If an outer macro calls an inner macro then the scope of the other macro is available to the running inner macro. That means that macro variables defined as LOCAL in the outer macro exist and are visible to the inner macro to read and modify. The exception is when the inner macro has its own LOCAL macro variable with the same name. The existence of that local macro variable will hide any macro variable(s) with the same name that exist in any currently running scope (including the GLOBAL scope).

If you nest the macro definitions the only impact will be that every time you call the outer macro then the inner macro will be re-compiled (needlessly).

I cannot think of any way that you could change the definition of that inner macro by placing the definition inside the definition of the outer macro. The only thing that I can think of that might have made it possible was a bug that impacted how macro variable references used in default values for parameters were handled. But that was fixed. Apparently the bug was introduced when they switched from PL/I to C compilers (early 80s?) and not fixed until just a few years ago. Shows much that type of functionality was ever used/needed.

Re: Nesting macro definitions

Kurt_Bremser — Fri, 06 Apr 2018 07:03:16 GMT

To keep my sanity, I have implemented this strategy for using macro variables in a macro:

There are these four types of variables:

macro variables that are actually parameters; these are by definition local
existing global macro variables used for overall control of the code; these must not be changed inside the macro, have a fixed definition and are known by all developers (eg type of an external host from which files are read - UNIX/Mainframe/Windows); they are usually set at program start in autoexec or similar
newly created variables for later global use, therefore appearing in a %global statement
local macro variables, named in a %local statement; this encompasses all variables not in one of the above categories. %local prevents side-effects

Other types of use are not allowed, to prevent unwanted side-effects.

There may be certain exceptions, but these need to be clearly described in comments when made.

In light of this, the way you use &a in the "inner" macro is a violation of these principles and MUST NOT HAPPEN. Pass it as a parameter.

And as others have said, all %macro definitions are stored in the global symbol table, so trying to "nest" macro definitions makes no sense. Nesting macro calls is of course possible and requires caution and planning. You can even call macros recursively:

%macro test(x);
%put X=&x;
%if &x < 5
%then %do;
  %let x = %eval(&x+1);
  %test(&x);
%end;
%mend;

%test(1)

Re: Nesting macro definitions

Astounding — Fri, 06 Apr 2018 11:21:04 GMT

It's easy enough to inspect the result. The main point that I (and pretty much all) posters are making is that this gives you the same result:

%macro outer;
	%global a;
	%let a = 10;

	%inner;
%mend;
%macro inner; 
   %global b; 
   %let b = 20; 
%mend inner; 
%outer;
%put &a &b;

There is no need to nest the definitions.

Re: Nesting macro definitions

gamotte — Fri, 06 Apr 2018 12:13:17 GMT

Hello,

I use macro nesting to create libraries of macro functions.

For instance I have a file my_lib.sas containing

%macro my_lib;

  %macro mac1(x);
    ...
  %mend;

  %macro mac2(y,z);
    ...
  %mend;

...

%mend my_lib;

Note that the file name (w.o. extension) has to be the same as the main macro name. That allows,

in an external program, to get access to a family of macros with a simple macro call

%my_lib

%mac1(10)

Do you consider it bad practice and if so, what would be the drawback ?

Re: Nesting macro definitions

Astounding — Fri, 06 Apr 2018 12:40:25 GMT

Here are some factors to consider.

Have you set up the SASAUTOS option to identify where %MY_LIB is stored? If you have, the other macros could also be made available without nesting by storing them in mac1.sas and mac2.sas. (If you haven't done this, SASAUTOS is a good tool to examine.)

Nesting the macro definitions gives you long files, making it more difficult to decipher the code.

Would %MAC1 and %MAC2 be valuable anywhere else, outside of %MY_LIB?

If you need to locate where %MAC1 and %MAC2 are defined, wouldn't that be easier if there are files named mac1.sas and mac2.sas?

Do any other macros (other than %MY_LIB) imbed definitions of "convenient names" such as %MAC1 and %MAC2? When you see %MAC1 or %MAC2 being used, do you know which version is being used?

Even if all these questions are easy for you to answer, would they be easy for someone else to answer as well?

Re: Nesting macro definitions

Tom — Fri, 06 Apr 2018 12:43:50 GMT

@gamotte wrote:

Hello,

I use macro nesting to create libraries of macro functions.

For instance I have a file my_lib.sas containing
%macro my_lib;

  %macro mac1(x);
    ...
  %mend;

  %macro mac2(y,z);
    ...
  %mend;

...

%mend my_lib;
Note that the file name (w.o. extension) has to be the same as the main macro name. That allows,

in an external program, to get access to a family of macros with a simple macro call

%my_lib

%mac1(10)

Do you consider it bad practice and if so, what would be the drawback ?

How does that help? You get the same effect if you just store all three definitions in the same source file without nesting them. When you %INCLUDE the file then all three are compiled. And if you are using autocall macros then you could store all three definitions in the file named 'my_lib.sas' (without nesting them) and they will be defined the first time you call '%my_lib'. SAS actually does this sometimes in the autocall library they provide.

I still don't like having multiple macro definitions in the same file. What is to prevent someone from creating a different version of %MAC1 and storing it in another file? Then you have a name conflict. If you store all of your macro definitions in individual files (in the same directory) then the operating system will prevent name collisions.

Re: Nesting macro definitions

gamotte — Fri, 06 Apr 2018 13:07:18 GMT

Thanks @Astounding and @Tom for your valuable input.

The idea of grouping several macros in the same file is that they concern a common subject.

We have a constraint that the directory structure that contains our programs is imposed by a norm

and we can not create sub directories to e.g. group macros by themes. As a result we have a small number

of directories each containing many programs, so reducing the number of programs is a desirable goal.

Those directories have indeed been declared in the SASAUTOS.

I understand the concern about macro names conflicts though it never occurred until now.

We have a precise naming scheme that should avoid this kind of problems to occur

but it is a good argument anyway.

The use of a macro call instead of an include is just personal taste.

Re: Nesting macro definitions

gamotte — Fri, 06 Apr 2018 13:12:25 GMT

@Tom wrote:

And if you are using autocall macros then you could store all three definitions in the file named 'my_lib.sas' (without nesting them) and they will be defined the first time you call '%my_lib'.

I have to check that because i think I already tried to do that and the compiler complained that the file contained no macro with the same name.

Re: Nesting macro definitions

Quentin — Fri, 06 Apr 2018 13:21:31 GMT

@gamotte wrote:

@Tom wrote:

And if you are using autocall macros then you could store all three definitions in the file named 'my_lib.sas' (without nesting them) and they will be defined the first time you call '%my_lib'.

I have to check that because i think I already tried to do that and the compiler complained that the file contained no macro with the same name.

Definitely works as Tom described. There should be one macro in the file where the macro name is the name of the file. Other helper macros can be defined in the same file after that. Even non-macro code can come after that and will be executed when the macro compiles. Basically with an autocall library, SAS %includes the file with the macro definition the first time you call the macro. There are risks of collisions as described.

Re: Nesting macro definitions

Tom — Fri, 06 Apr 2018 13:22:15 GMT

@gamotte wrote:

@Tom wrote:

And if you are using autocall macros then you could store all three definitions in the file named 'my_lib.sas' (without nesting them) and they will be defined the first time you call '%my_lib'.

I have to check that because i think I already tried to do that and the compiler complained that the file contained no macro with the same name.

It definitely works. The autocall process will hunt for the filename corresponding to the unknown macro's name and sources the files contents and then proceeds to call the macro. The error message you mentioned happens if the macro doesn't get defined. So if you saved your example into mac1.sas instead of my_lib.sas. In that case just including the source wouldn't define mac1 since its definition was hidden inside of the definition of my_lib.

Re: Nesting macro definitions

Kurt_Bremser — Fri, 06 Apr 2018 13:29:44 GMT

I'd NEVER do that. Use the autocall (or any SAS code) library in the usual way (1 macro -> 1 file). Just think of the nightmare of keeping such a convolution in a versioning system.

Re: Nesting macro definitions

Tom — Fri, 06 Apr 2018 13:33:54 GMT

@gamotte wrote:

Thanks @Astounding and @Tom for your valuable input.

The idea of grouping several macros in the same file is that they concern a common subject.

We have a constraint that the directory structure that contains our programs is imposed by a norm

and we can not create sub directories to e.g. group macros by themes. As a result we have a small number

of directories each containing many programs, so reducing the number of programs is a desirable goal.

Those directories have indeed been declared in the SASAUTOS.

I understand the concern about macro names conflicts though it never occurred until now.

We have a precise naming scheme that should avoid this kind of problems to occur

but it is a good argument anyway.

The use of a macro call instead of an include is just personal taste.

In past we have imposed naming conventions that make it clear if a macro is just a helper macro for a main macro. For example by prefixing the name of the main macro. So in your example you would have macros names %MYMAC, %MYMAC_MAC1, %MYMAC_MAC2 and the source could would be in files mymac.sas, mymac_mac1.sas, and mymac_mac2.sas

Re: Nesting macro definitions

gamotte — Fri, 06 Apr 2018 14:10:26 GMT

Sorry, I'm a bit slow.

If I, for instance, define a library for handling a users database, with three

macros : %user_add, %user_del, %user_update. I can define the three macros in a

file user_management.sas. AUTOCALL would not work because there is no macro

%user_management.

If I decide to rename my file user_add.sas, AUTOCALL would work but i would have to

add a user prior to any other action which may be not what I want.

I could create an empty macro %user_management or ... use a nesting macro.

The empty macro just seemed a bit strange to me hence the choice of nesting.

Anyway, I am not advocating any solution over another. I perfectly understand the recommandation

of one macro per sas program. Grouping several macros in teh same program is just the workaround we

found to organize our macros without the possibility of acting on the directory structure.

Re: Nesting macro definitions

Tom — Fri, 06 Apr 2018 14:22:07 GMT

@gamotte wrote:

Sorry, I'm a bit slow.

If I, for instance, define a library for handling a users database, with three

macros : %user_add, %user_del, %user_update. I can define the three macros in a

file user_management.sas. AUTOCALL would not work because there is no macro

%user_management.

If I decide to rename my file user_add.sas, AUTOCALL would work but i would have to

add a user prior to any other action which may be not what I want.

I could create an empty macro %user_management or ... use a nesting macro.

The empty macro just seemed a bit strange to me hence the choice of nesting.

Anyway, I am not advocating any solution over another. I perfectly understand the recommandation

of one macro per sas program. Grouping several macros in teh same program is just the workaround we

found to organize our macros without the possibility of acting on the directory structure.

If you are using autocall and your file is named user_management then it needs to have a macro definition in it for the macro %user_management. If what it contains is the definition of other macros then every time you call it those macro will be re-defined, which is just a waste. It also makes the file more confusing because there is an extra level of nesting you need worry about.

%macro user_management;
%put NOTE: You can now use the macros %str( %user_add, %user_del, and %user_update.);
%mend user_mangement;

%macro user_add

%mend user_add;

...

Re: Nesting macro definitions

SAS_inquisitive — Fri, 06 Apr 2018 14:43:33 GMT

@Tom. I tested it out here. Thanks !

%macro outer;
	%local a;
	%let a = 10;

	%macro inner;
		%let b = 10;
		%let total = %eval(&a + &b);
		%put &total;
	%mend inner;
	%inner;
%mend outer;
%outer;

Re: Nesting macro definitions

Tom — Fri, 06 Apr 2018 14:54:19 GMT

@SAS_inquisitive wrote:

@Tom. I tested it out here. Thanks !

%macro outer;
	%local a;
	%let a = 10;

	%macro inner;
		%let b = 10;
		%let total = %eval(&a + &b);
		%put &total;
	%mend inner;
	%inner;
%mend outer;
%outer;

You will get the same result without nesting the DEFINITIONS.

%macro inner;
  %let b = 10;
  %let total = %eval(&a + &b);
  %put &total;
%mend inner;
%macro outer;
  %local a;
  %let a = 10;
  %inner;
%mend outer;

%outer;