topic Re: macro to send email with option ATTACH not fill in in SAS Programming

macro to send email with option ATTACH not fill in

Nasser_DRMCP — Thu, 05 Apr 2018 11:04:48 GMT

hello,

%macro mc_email (to=, from=, cc=, subject=, sender=, texte=, expediteur=, attach=) ;

DATA _null_ ;
slept= sleep(120);
run;

data _null_;
filename mail email to=(&to.) from=&from.
cc=(&cc.)
subject=&subject.
sender=&sender.
ATTACH= (&attach.)
;

file mail;
put 'Bonjour,' ; 
put ' ' ;
put "&texte." ; 
put ' ' ;
put 'Cordialement,' ;
put ' ' ;
put "&expediteur." ;
run;

%mend mc_email ;


%mc_email(  to = &mv_email_destinataire_list, 
		                from = "Mr Nasser",        
		                  cc = &mv_email_copie_list,                    
		             subject = "Execution ra_retention : OK",
		              sender = "lauch_ra_retention.sas",
		               texte = Le programme s est déroulé sans erreur,
		          expediteur = Mr Nasser ,
					attach= );

I call this macro by specifiying a file in the "attach" option--> it works
I call this macro by NOT specifiying a file in the "attach" option--> it DOES NOT works.

What could I do to make this macro working for both options ("attach" fill in or not) ?

thanks a lot in advance for your help

Re: macro to send email with option ATTACH not fill in

Kurt_Bremser — Thu, 05 Apr 2018 11:14:14 GMT

Use a condition:

data _null_;
filename mail email to=(&to.) from=&from.
cc=(&cc.)
subject=&subject.
sender=&sender.
%if "&attach." ne "" %then %do;
ATTACH= (&attach.)
%end;
;

Re: macro to send email with option ATTACH not fill in

Nasser_DRMCP — Thu, 05 Apr 2018 11:25:29 GMT

Hello Kurt and thanks for your quick repsonse.

I test your solution.

without specifiied file, it works. but by specifying a file like

attach= "/home/ldap/mellouna/lance_prog_cdgr.log" I got an error message

ERROR: A character operand was found in the %EVAL function or %IF condition where a numeric operand is required. The condition was:

"&attach." ne ""

Re: macro to send email with option ATTACH not fill in

Kurt_Bremser — Thu, 05 Apr 2018 11:34:43 GMT

You can omit the double quotes:

%if &attach. ne  %then %do;
ATTACH= (&attach.)
%end;

Re: macro to send email with option ATTACH not fill in

Nasser_DRMCP — Thu, 05 Apr 2018 11:42:55 GMT

It works perfectly thanks !