topic Re: Get rid of initial string in SAS Programming

Get rid of initial string

MarcTC — Tue, 21 Dec 2010 21:29:45 GMT

I am wondering if there is a simple statement which can do the following conversion.

If a string begins with X's, then get rid of all initial X's.

Some examples here:

XDANO => DANO
XXQRX => QRX
XMKR => MKR
XXXDMZ => DMZ
CANE => CANE

Re: Get rid of initial string

chang_y_chung_hotmail_com — Tue, 21 Dec 2010 21:44:35 GMT

Here is one way.

data _null_;

length x y $8;

do x = "", "A", "XDANO", "XXQRX", "XMKR";

y = prxchange("s|^X+||",1,x);

put x= @10 y=;

end;

run;

/* on log

x= y=

x=A y=A

x=XDANO y=DANO

x=XXQRX y=QRX

x=XMKR y=MKR

Re: Get rid of initial string

RickM — Tue, 21 Dec 2010 21:54:21 GMT

Here is another solution.

Good luck!

[pre]
data one;
input names $;
datalines;
XDANO
XXQRX
XMKR
XXXDMZ
CANE
;

data two;
set one;
do while (upcase(char(names,1)) eq "X");
names=substr(names,2);

end;
run;
[/pre]

Re: Get rid of initial string

MarcTC — Tue, 21 Dec 2010 21:54:50 GMT

Thanks, this is great!

Re: Get rid of initial string

Ksharp — Wed, 22 Dec 2010 07:57:00 GMT

Hi.
I have another choice.

[pre]
data one;
input names $;
datalines;
XDANO
XXQRX
XMKR
XXXDMZ
CANE
;
run;
data one;;
set one;
if upcase(names) eq : 'X' then names=substr(names,verify(names,'xX'));
put names=;
run;

*or just more explicit and simple;
data one;;
set one;
names=substr(names,verify(names,'xX'));
put names=;
run;

[/pre]

Ksharp Message was edited by: Ksharp