topic Re: Keep a list of variables in SAS Programming

Keep a list of variables

hhchenfx — Thu, 29 Mar 2018 15:32:36 GMT

Hi Everyone,

I have 2 files. One is a big datafile, and one is the list of variable name and want to keep.

basically I want something like that

data want; set bigfile;

keep a b c; run;

But the list is long and keep in the second file.

Can you help me with that?

Thank you,

HHCFX

I try to transpose and create a temp code like "KEEP a b c ;"

then do

data want ; set bigdata;
%include tmp;
;run;

but dont know how to create that "KEEP a b c ;"


data bigdata; 
input a b c d e f;
datalines;
1 2 3 4 5 6
;run;


data listvar; 
input var $;
datalines;
a
b
c
;run;

Re: Keep a list of variables

ballardw — Thu, 29 Mar 2018 15:38:32 GMT

One way:

data bigdata; 
input a b c d e f;
datalines;
1 2 3 4 5 6
;run;

data listvar; 
input var $;
datalines;
a
b
c
;
run;
proc sql noprint;
    select var into: varlist separated by ' '
    from listvar;
quit;

data smalldata;
   set bigdata (keep=&varlist.);
run;

Re: Keep a list of variables

PaigeMiller — Thu, 29 Mar 2018 15:39:31 GMT

proc sql noprint;
    select distinct var into :varnames separated by ' ' from listvar;
quit;

data bigdata;
    set bigdata(keep=&varnames);
run;

Re: Keep a list of variables

Reeza — Thu, 29 Mar 2018 15:42:57 GMT

1. Create a macro variable list from listvar table - see PROC SQL create macro variables in the documentation.

See example 3 in the documentation here:

http://documentation.sas.com/?docsetId=mcrolref&docsetTarget=n1y2jszlvs4hugn14nooftfrxhp3.htm&docsetVersion=9.4&locale=en#n0siuil5847r0fn10mbzm8h238ox

2. Use that macro variable in a Keep statement.

keep &keep_list;

Re: Keep a list of variables

art297 — Thu, 29 Mar 2018 15:53:31 GMT

You already have a solution, but I noticed that no one showed you how to accomplish the task the way you originally wanted to do it. Here is one way:

data keepers;
  input keepers $;
  datalines;
Name
age
;

data _null_;
  file '/folders/myfolders/keepers.sas';
  set keepers end=lastone;
  if _n_ eq 1 then put 'keep';
  put keepers;
  if lastone then put ';';
run;

data want;
  set sashelp.class;
  %inc '/folders/myfolders/keepers.sas';
run;

Art, CEO, AnalystFinder.com

Re: Keep a list of variables

hhchenfx — Thu, 29 Mar 2018 16:10:12 GMT

Thank you,

I thought I will you some sort of transpose, array, then catt() to add these var together.