topic Re: Indicate decades from dates in SAS Programming

Indicate decades from dates

Miah — Mon, 05 Mar 2018 04:07:09 GMT

I am working with the data set TopGrossingAlbumsR.txt, triying to create a new character variable that indicates the decade when the album was released.

I am not sure about the right way to approach this question. How should I initialize the char variable? how could I specify the date format in the IF statement and finally, how could I assign the value of decade to my new variable?

The values of 'ReleaseDate' are written in the format: 30NOV1982

I want my new char variable 'Decade' to indicate 1980 for this example.

Here it is my code and I have attached the data set below:

DATA music;
INFILE '/folders/myfolders/TopGrossingAlbumsR.txt' dsd firstobs=2;
LENGTH Album $80. Artist $50. Genre $20.;
INFORMAT ReleaseDate ANYDTDTE.;
FORMAT ReleaseDate DATE9.;

INPUT Album Artist ReleaseDate TotalCertifiedCopies ClaimedSales Genre;
RUN;

PROC PRINT DATA = music;
	FORMAT ReleaseDate DATE. ;
RUN;

DATA music;
   SET music;
   Decade = ' ';

   IF ReleaseDate = ' ' THEN Decade = YYYY;
   
   IF Genre = 'Metal' THEN Genre = 'Rock';
   IF Genre = 'Grunge' THEN Genre = 'Rock';
   IF Genre = 'Soundtrack' THEN Genre = 'Other';
   IF Genre = 'Country' THEN Genre = 'Other';
RUN; 

PROC PRINT DATA = music;
RUN;

Re: Indicate decades from dates

Reeza — Mon, 05 Mar 2018 03:57:27 GMT

First explain in words what you want.

Then show the data, then the code.

So, if you have 1990, what do you want, 90? 1990?

If 2000, do you want 00? or 2000?

How will you tell 2010 from 1910?

@Miah wrote:

I am working with the data set TopGrossingAlbumsR.txt, triying to create a new character variable that indicates the decade when the album was released.

I am not sure about the right way to approach this question. How should I initialize the char variable? how could I specify the date format in the IF statement and finally, how could I assign the value of decade to my new variable?

Here it is my code and I have attached the data set below:
DATA music;
INFILE '/folders/myfolders/TopGrossingAlbumsR.txt' dsd firstobs=2;
LENGTH Album $80. Artist $50. Genre $20.;
INFORMAT ReleaseDate ANYDTDTE.;
FORMAT ReleaseDate DATE9.;

INPUT Album Artist ReleaseDate TotalCertifiedCopies ClaimedSales Genre;
RUN;

PROC PRINT DATA = music;
	FORMAT ReleaseDate DATE. ;
RUN;

DATA music;
   SET music;
   Decade = ' ';

   IF ReleaseDate = ' ' THEN Decade = YYYY;
   
   IF Genre = 'Metal' THEN Genre = 'Rock';
   IF Genre = 'Grunge' THEN Genre = 'Rock';
   IF Genre = 'Soundtrack' THEN Genre = 'Other';
   IF Genre = 'Country' THEN Genre = 'Other';
RUN; 

PROC PRINT DATA = music;
RUN;

Re: Indicate decades from dates

Miah — Mon, 05 Mar 2018 04:07:40 GMT

The values of 'ReleaseDate' are written in the format: 30NOV1982

I want my new char variable 'Decade' to indicate 1980 for this example.

Re: Indicate decades from dates

Reeza — Mon, 05 Mar 2018 04:07:55 GMT

decade = floor(year(date)/10) * 10 ;

Re: Indicate decades from dates

PGStats — Mon, 05 Mar 2018 04:10:30 GMT

Do this the cool way with intnx("year10", ...)


DATA music;
   SET music;
   Decade = intnx("year10", releaseDate, 0);
   length decadeTxt $4;
   decadeTxt = cats("'", put(decade, year2.), "s");
   IF Genre = 'Metal' THEN Genre = 'Rock';
   IF Genre = 'Grunge' THEN Genre = 'Rock';
   IF Genre = 'Soundtrack' THEN Genre = 'Other';
   IF Genre = 'Country' THEN Genre = 'Other';
   format decade year2.;
RUN;

Re: Indicate decades from dates

Miah — Mon, 05 Mar 2018 04:47:10 GMT

This was straight forward what I needed. Thanks!

Re: Indicate decades from dates

novinosrin — Mon, 05 Mar 2018 06:21:14 GMT

data want;
set have;
decade=year(releaseDate)-mod(year(releaseDate),10);
run;

Re: Indicate decades from dates

Kurt_Bremser — Mon, 05 Mar 2018 10:14:12 GMT

@Reeza wrote:

decade = floor(year(date)/10) * 10 ;

Perfect application of the KISS principle.