topic Re: Macro works, but error message received. in SAS Programming

Macro works, but error message received.

Haikuo — Thu, 23 Feb 2012 17:15:03 GMT

The original discussion was on SAS-L. The OP wanted to replace blanks with ',' in his macro variable strings.

eg. Have: %let a=a b c d; Want a=a,b,c,d.

So I came up with the following Macro:

%macro com (a=);

%let a1=;

%do i=1 %to %sysfunc(countw(&a));

%let a1=%sysfunc(catx(%str(,),&a1,%scan(&a,&i)));

%end;

%let a=&a1;

%put &a;

%mend;

%com (a=a b c d)

It works for the purpose, but it generate an error message as:

ERROR: %SYSEVALF function has no expression to evaluate.

Please help me to figure it out why.

Thanks in advance,

Haikuo

Macro works, but error message received.

Astounding — Thu, 23 Feb 2012 17:42:26 GMT

Haikuo,

OK, first I have to comment and then I'll make a guess as to the cause.

This is a very dangerous macro to use. It is missing this key statement:

%local a1 i;

If I were to call this macro, it would change the value of existing macro variables named &A1 or &I. Those macro variables might exist in the %GLOBAL symbol table, or they might exist in the %LOCAL symbol table for a macro that calls this macro. But that is what makes this macro dangerous to use.

My guess as to where the error comes from is the first pass through the %DO loop, when &A1 is null. To test this (I can't, I'm home today), try these changes.

What's there now:

%let a1=;

%do i=1 %to ...;

Try this instead:

%let a1=%scan(&a,1);

%do i=2 %to ...;

See if the error disappears.

Re: Macro works, but error message received.

Haikuo — Thu, 23 Feb 2012 17:49:59 GMT

Thanks, Astounding. Comments well received. So What it means is that %sysfunc has problem with macro variable of null value, but still process it reluctanly?

Macro works, but error message received.

Astounding — Thu, 23 Feb 2012 17:52:58 GMT

My guess:

%sysfunc in combination with catx is calling %sysevalf in a way that we cannot see.

It's a sort of a black box. We can see what goes in and what comes out, but can only guess at the internal workings.

Re: Macro works, but error message received.

FriedEgg — Thu, 23 Feb 2012 18:56:49 GMT

15 %let a=1 2 3 4;

16 %put original -> &a;

original -> 1 2 3 4

18 %let a=%sysfunc(prxchange(%quote(s/\s+/,/),-1,&a));

19 %put prxchange -> &a;

prxchange -> 1,2,3,4

21 %let a=%sysfunc(translate(%quote(&a),'2c'x,'20'x));

22 %put translate -> &a;

translate -> 1,2,3,4

Re: Macro works, but error message received.

Ksharp — Fri, 24 Feb 2012 06:27:06 GMT

Actually. you don't need function catx();

%macro com (a=);

%let a1=%scan(&a,1);

%do i=2 %to %sysfunc(countw(&a));

%let a1=&a1.,%scan(&a,&i);

%end;

%let a=&a1;

%put &a;

%mend;

%com (a=a b c d)

Ksharp

Re: Macro works, but error message received.

Haikuo — Fri, 24 Feb 2012 12:39:25 GMT

Good call, Ksharp!