topic How to convert Character data with trailing sign to Numeric data in SAS Programming

How to convert Character data with trailing sign to Numeric data

SASInd — Sat, 24 Feb 2018 18:46:29 GMT

Hi All,

I have a requirement where the input is coming from the Easytrieve in which the acceptable numeric format is 100.00-. I need to convert this into SAS numeric format. Can some one help me in achieving this?

Input Output

100.00- -100.00

This field is the variable one.

Re: How to convert Character data to Numeric data.

PGStats — Sat, 24 Feb 2018 05:49:12 GMT

You can define your own informat to read such numbers


/* Informat function to read numbers possibly suffixed with a
   minus sign. */ 
proc fcmp outlib=work.fcmp.format;
function EasytrieveNumber(text $);
m = indexc(text, "-");
if m = length(text) then return (-input(substr(text,1,m-1), best.));
else return (input(text, best.));
endsub;
run;

options cmplib=(work.fcmp);

proc format;
invalue EasytrieveNumber(default=32) 
OTHER = [EasytrieveNumber()];
run;

data have;
input a :EasytrieveNumber10.;
format a 8.2;
cards;
100.00-
100.00
;

proc print data=have; run;

                                  Obs           a

                                   1      -100.00
                                   2       100.00

Re: How to convert Character data to Numeric data.

Ksharp — Sat, 24 Feb 2018 06:03:38 GMT

data x;
input x trailsgn32.;
cards;
100.00-   
34.32-
29
64.89
;
run;
proc print;run;

Re: How to convert Character data to Numeric data.

SASInd — Sat, 24 Feb 2018 07:52:04 GMT

Hi Ksharp,

TRAILSGNw. will only work for numeric values. In this case the input is coming as 100.00- which in my knowledge will only be read as a character value.

Thanks!

Re: How to convert Character data to Numeric data.

error_prone — Sat, 24 Feb 2018 16:17:27 GMT

@SASInd: @Ksharp demonstrates that the format can be used to create normal numbers.

Re: How to convert Character data to Numeric data.

SASInd — Sat, 24 Feb 2018 16:47:03 GMT

Yeah... But the question here is for converting the character data to a numeric format.

Re: How to convert Character data to Numeric data.

Reeza — Sat, 24 Feb 2018 17:32:21 GMT

@aadityapurohit3 wrote:
Yeah... But the question here is for converting the character data to a numeric format.

That's what @Ksharp solution does, you can use that format in the INPUT() statement.

data x;
    input x $;
    cards;
100.00-   
34.32-
29
64.89
;
run;

data want;
    set x;
    char_x=input(x, trailsgn32.);
run;

proc print data=want;
run;

Re: How to convert Character data to Numeric data.

SASInd — Tue, 27 Feb 2018 09:52:37 GMT

Thank you @Ksharp @error_prone & @Reeza 🙂