topic Re: how to read Timestamp format of YYYY/MM/DD HH:MM:SS in SAS Programming

how to read Timestamp format of YYYY/MM/DD HH:MM:SS

yashk — Mon, 12 Feb 2018 21:05:01 GMT

data test;
input calendar_date DATETIME.;
cards;
2017/01/01 01:01:50
2017/01/02 05:06:30
;
run;

I tried with a lot of different formats for this. But always i am getting a missing data. Any help is appreciated. Thank you.

Re: how to read Timestamp format of YYYY/MM/DD HH:MM:SS

Reeza — Mon, 12 Feb 2018 21:10:37 GMT

Read them separately and combine after the fact?

You

data test;
input calendar_date yymmdd10. calendar_time time.;
format calendar_date date9. calendar_time time. calendarDT datetime.;
calendarDT=dhms(calendar_date, 0, 0, calendar_time);
cards;
2017/01/01 01:01:50
2017/01/02 05:06:30
;
run;

proc print data=test;
run;

Or you can try ANYDTDTM. - note that this assumes that your date is yymmdd, but it could be yyddmm but that's extremely rare to se. The current date format is not what SAS would consider DATETIME.

data test;
input calendar_date  anydtdtm.;

format calendar_date datetime.;
cards;
2017/01/01 01:01:50
2017/01/02 05:06:30
;
run;

proc print data=test;
run;

@yashk wrote:

data test;
input calendar_date DATETIME.;
cards;
2017/01/01 01:01:50
2017/01/02 05:06:30
;
run;

I tried with a lot of different formats for this. But always i am getting a missing data. Any help is appreciated. Thank you.

Re: how to read Timestamp format of YYYY/MM/DD HH:MM:SS

PeterClemmensen — Mon, 12 Feb 2018 21:13:11 GMT

data test;
input calendar_date :anydtdtm.;
format calendar_date datetime20.;
cards;
2017/01/01 01:01:50
2017/01/02 05:06:30
;
run;

Re: how to read Timestamp format of YYYY/MM/DD HH:MM:SS

yashk — Tue, 13 Feb 2018 02:30:36 GMT

Great idea. Thank you. But i believe we cannot perform calculations if we combine variables. I tried below similar below but i was unable to perform calculations on the new variable.

data test;
input calendar_date yymmdd10. calendar_time time.;
Combined=catx(' ',put(calendar_date,yymmdd10.), put(calendar_time,time.));
cards;
2017/01/01 01:01:50
2017/01/02 05:06:30
;

run;

proc print data=test;
format calendar_Date yymmdd10. calendar_time time.;
run;

Re: how to read Timestamp format of YYYY/MM/DD HH:MM:SS

Reeza — Tue, 13 Feb 2018 03:12:47 GMT

But i believe we cannot perform calculations if we combine variables

That's incorrect. You combined the variables together using CATX() - this creates a character variable, which you cannot perform numerical calculations.

I used the DHMS() function which returns a SAS datetime or a number which you can use for date/time calculations.

@yashk wrote:

Great idea. Thank you. But i believe we cannot perform calculations if we combine variables. I tried below similar below but i was unable to perform calculations on the new variable.

data test;
input calendar_date yymmdd10. calendar_time time.;
Combined=catx(' ',put(calendar_date,yymmdd10.), put(calendar_time,time.));
cards;
2017/01/01 01:01:50
2017/01/02 05:06:30
;

run;

proc print data=test;
format calendar_Date yymmdd10. calendar_time time.;
run;