topic Problem using yymmdd11. informat in SAS Programming

Problem using yymmdd11. informat

slolay — Fri, 09 Dec 2011 12:50:19 GMT

I have a text variable containg dates in the format:

YYYY-MMM-DD

2011-FEB-14

2002-SEP-22

etc

I'm trying to convert these to SAS dates using input statement but get invalid data message for the INPUT statement

Any help on how to get this working

data test;

date1='2011-AUG-12';

date2=input(date1,yymmdd11.);

run;

Thanks
Steve

Problem using yymmdd11. informat

BrunoMueller — Fri, 09 Dec 2011 15:12:36 GMT

Hi Steve

I do not know of a format, but you can write a function to make a SAS date value out of the string, see sample below:

proc fcmp outlib=work.myFunctions.dates;
  function xDate( date $);
    length dlm $ 1; 
    dlm = "-"; 
    year = scan(date, 1, dlm);
    month = scan(date, 2, dlm);
    day = scan(date, 3, dlm);
    newDate = cats(day, month, year);
    newDate_N = input(newDate, date9.);
    return(newDate_N);
  endsub; 
run; 


options
  cmplib=(work.myFunctions)
;


data testFunction;
  date1 = '2011-AUG-12'; 
  date2 = xDate(date1);
  format date2 date9.; 
run;

Bruno

Re: Problem using yymmdd11. informat

jcheema — Fri, 09 Dec 2011 16:28:32 GMT

How about:

data test;

date1='2011-AUG-12';

date2=input(substr(date1,10,2)||substr(date1,6,3)||substr(date1,1,4),date9.);

put date1= date2= ;

run;

Problem using yymmdd11. informat

FriedEgg — Fri, 09 Dec 2011 18:07:00 GMT

anydtdte11.

Problem using yymmdd11. informat

Linlin — Fri, 09 Dec 2011 18:23:08 GMT

data test;

date1='2011-AUG-12';

date2=input(date1,anydtdte11.);

format date2 mmddyy10.;

run;

proc print;run;

Problem using yymmdd11. informat

slolay — Mon, 12 Dec 2011 11:05:28 GMT

Thanks - does the job!...now to read up on it......

Problem using yymmdd11. informat

art297 — Mon, 12 Dec 2011 13:55:51 GMT

Not a lot to look up on it (http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a002605538.htm), but the anydtdte informat appears to be able to read dates that give all of the other date informats problems. A useful system option to supplement it is the:

options datestyle=mdy

in order to guide the informat regarding the order of the three date parts.